Re: Aus Acces Daten in Excel einlesen.Geht das?
06.02.2003 20:32:32
Bernd Held
Hallo Johann,ich kann Dir eine Lösung anbieten, mit der du eine Access-Tabelle direkt in Excel einlesen kannst.Vielleicht für Dich ein Ansatz.
Sub MitarbeiterlisteErstellen()
Dim ADOC As ADODB.Connection
Dim DBS As ADODB.Recordset
Dim s As String
Dim Pfad As String
Dim i As Integer
ChDir ThisWorkbook.Path
Set ADOC = New ADODB.Connection
With ADOC
.Provider = "Microsoft.Jet.OLEDB.4.0"
.Open "Infosystem.mdb"
End With
Set DBS = New ADODB.Recordset
With DBS
.Open Source:="Mitarbeiter", _
ActiveConnection:=ADOC, _
CursorType:=adOpenKeyset, _
LockType:=adLockOptimistic
i = 2
Sheets("Mitarbeiter Gesamt").Activate
If Not .EOF Then
Do While Not .EOF
Cells(i, 1).Value = DBS!Name
Cells(i, 2).Value = DBS!Vorname
Cells(i, 3).Value = DBS!Straße
Cells(i, 4).Value = DBS!PLZ
Cells(i, 5).Value = DBS!Ort
Cells(i, 6).Value = DBS!Gebäude
Cells(i, 7).Value = DBS!Etage
Cells(i, 8).Value = DBS!ZimmerNr
Cells(i, 9).Value = DBS!Telefon
Cells(i, 10).Value = DBS!Fax
Cells(i, 11).Value = DBS!Mail
i = i + 1
.MoveNext
Loop
Else
MsgBox "Datensatz nicht gefunden"
End If
.Close
End With
ADOC.Close
Set DBS = Nothing
Set ADOC = Nothing
End Sub
Viele Grüße
Bernd
MVP für Microsoft Excel
Excel-Tipps, VBA in 21 Tagen und VBA-Datenbank unter: http://held-office.de