Formel SVERWEIS mehrspaltig klappt nicht

Forumthread: Formel SVERWEIS mehrspaltig klappt nicht

Volker

Hallo,
die Formel für "SVERWEIS bei mehrspaltigen Suchkriterien" klappt bei mir nicht.
{=INDEX(C1:C1000;VERGLEICH("x"&"y";A1:A1000&B1:B1000;0))}
Das "&" zwischen den Spalten A und B interpretiert mein Excel als Verkettung von Texten.
Kann man das "beheben"?
Gruß,
Volker

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: Formel SVERWEIS mehrspaltig klappt nicht

Boris

Hi Volker,
Das "&" zwischen den Spalten A und B interpretiert mein Excel als Verkettung von Texten.
Da kann ich dich beruhigen - auch mein Excel "verkettet" mit "&"...;-)
Was erwartest du?
Grße Boris

AW: Formel SVERWEIS mehrspaltig klappt nicht

Volker

Hallo Boris,
okay, ich habe das recht knapp geschildert.
Ich erwarte folgendes: Suche in Spalte A, in welcher Zeile "x" steht, und suche in Spalte B, in welcher Zeile "y" steht. Das Ergebnis soll sein, was in Spalte C in derselben Zeile steht.
Das Beispiel findest Du auch unter:
http://www.excelformeln.de/formeln.html?welcher=30
Grüße,
Volker

Das ist eine Array-Formel !

Hi Volker,
Eingabe Array-Formel:
Du kopierst Dir die Formel.,
Dann gehst Du in die Bearbeitungszeile, löschst die {geschweiften Klammern} am Anfang und Ende und schließt ab mit GLEICHZEITIG: Strg Shift Enter (statt Enter allein). Dadurch werden diese Klammern erzeugt.
Salut WF

AW: Das ist eine Array-Formel !

29.04.2004 13:56:10

Volker

Hi WF,
das war's. Muchas Gracias!
Werde nie wieder Level "Excel gut" angeben;-)
Grüße,
Volker

AW: was suchst Du? - eine kleine Formelsammlung

Hallo Volker,
wenn in Spalte A x und in Spalte B y in der selben Zeile steht und dies mehrfach der Fall ist, dann...

	A	B	C	D	E
1	a	a	1	4	<- wie oft steht x (in A) in der selben Zeile wie y (in B)
2	b	b	2	11	<- der größte Trefferwert
3	y	x	3	9	<- der 2.größte Trefferwert
4	x	y	11	1	<- wenn nur der kleinste Treffer gesucht ist
5	e	c	5	11	<- wenn nur der größte Treffer gesucht ist
6	f	d	6	11	<- wenn nur Treffer #1 gesucht ist
7	x	y	4	1	<- wenn nur der letzte Treffer gesucht ist
8	y	x	8	1	<- der kleinste Trefferwert
9	x	y	9	4	<- der 2.kleinste Trefferwert
10	x	y	1	9	<- der 3.kleinste Trefferwert
11				11	<- der 4.kleinste Trefferwert
12				11	<- Treffer #1
13				4	<- Treffer #2
14				9	<- Treffer #3
15				1	<- Treffer #4

Formeln der Tabelle

D1 : =SUMMENPRODUKT(N(A1:A100&B1:B100="xy"))
D2 : {=WENN(ZEILEN($1:1)>$D$1;"";KGRÖSSTE((A$1:A$100&B$1:B$100="xy")*C$1:C$100;ZEILEN($1:1)))}
D3 : {=WENN(ZEILEN($1:2)>$D$1;"";KGRÖSSTE((A$1:A$100&B$1:B$100="xy")*C$1:C$100;ZEILEN($1:2)))}
D4 : {=MIN(WENN(A1:A100&B1:B100="xy";C1:C100))}
D5 : {=MAX((A1:A100&B1:B100="xy")*C1:C100)}
D6 : {=INDEX(C:C;VERGLEICH("xy";A1:A100&B1:B100;0))}
D7 : {=INDEX(C:C;MAX(("xy"=A1:A100&B1:B100)*ZEILE(1:100)))}
D8 : {=KKLEINSTE(WENN(A$1:A$100&B$1:B$100="xy";C$1:C$100);ZEILEN($1:1))}
D9 : {=KKLEINSTE(WENN(A$1:A$100&B$1:B$100="xy";C$1:C$100);ZEILEN($1:2))}
D10 : {=KKLEINSTE(WENN(A$1:A$100&B$1:B$100="xy";C$1:C$100);ZEILEN($1:3))}
D11 : {=KKLEINSTE(WENN(A$1:A$100&B$1:B$100="xy";C$1:C$100);ZEILEN($1:4))}
D12 : {=INDEX(C:C;KKLEINSTE(WENN(A$1:A$100&B$1:B$100="xy";ZEILE($1:$100));ZEILEN($1:1)))}
D13 : {=INDEX(C:C;KKLEINSTE(WENN(A$1:A$100&B$1:B$100="xy";ZEILE($1:$100));ZEILEN($1:2)))}
D14 : {=INDEX(C:C;KKLEINSTE(WENN(A$1:A$100&B$1:B$100="xy";ZEILE($1:$100));ZEILEN($1:3)))}
D15 : {=INDEX(C:C;KKLEINSTE(WENN(A$1:A$100&B$1:B$100="xy";ZEILE($1:$100));ZEILEN($1:4)))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Ist das nicht eine nette kleine Formelsammlung ?
Servus aus dem Salzkammergut
Franz

Beliebteste Forumthreads (12 Monate)

Formel SVERWEIS mehrspaltig klappt nicht

Forumthread: Formel SVERWEIS mehrspaltig klappt nicht

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Formel SVERWEIS mehrspaltig klappt nicht

Forumthread: Formel SVERWEIS mehrspaltig klappt nicht

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread