Grafik aus Zahlenreihen erstellen

Forumthread: Grafik aus Zahlenreihen erstellen

20.12.2004 17:06:34

Simon

Hallo,
meine Tabelle hat ca. folgenden Aufbau:
A B
1 100
2 332
3 232
1 335
2 693
3 234
1 982
2 212
3 698
... ...
In Spalte A steht quasi der Index (1,2 oder 3) in Spalte B ein Wert.
Jetzt möchte ich ein Diagramm erstellen, welches für jeden Index eine Kurve der dazugehörigen Werte darstellt.
Zusätzlich soll ein Index bei dem sich die Werte nie ändern ignoriert werden.
Ich glaub ich brauche nicht zu erwähnen, dass es sich um viel mehr Daten handelt, deshalb möchte ich es gern automatisieren. (Index 1-200, pro Index ca. 1000 Werte)
Vielen Dank für Eure Hilfe,
Simon

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Grafik aus Zahlenreihen erstellen

Volker

Hallo Simon,
wie kommen denn die Werte in deine Tabelle?
Wenn der Index wirklich bis 200 geht macht das nämlich bei je 1000 Werten 200000 Werte untereinander. Soviele Zeilen hat keine Tabelle.
Schau mal, ob Du dich da nicht vertan hast.
Gruß
Volker

AW: Grafik aus Zahlenreihen erstellen

ChrisL

Hi Simon
Index muss Zahl 1-200 und Daten am richtigen Ort sein (wie in deinem Beispiel) damit es funktioniert.
Gruss
Chris


Sub Simsalabim()
Dim WS1 As Worksheet, WS2 As Worksheet
Dim Diagramm As Chart
Dim iZeile As Long, iSpalte As Integer
Dim LetzteZeile As Long
Application.ScreenUpdating = False
Set WS1 = Worksheets("TabelleDaten") ' <-- Name der Ausgangstabelle
' Tabelle 'Hilfstabelle' erstellen
If WSVorhanden("Hilfstabelle") Then
Set WS2 = Worksheets("Hilfstabelle")
WS2.Rows("2:65536").ClearContents
Else
Set WS2 = Sheets.Add
WS2.Name = "Hilfstabelle"
For iSpalte = 1 To 200
WS2.Cells(1, iSpalte) = "Index " & iSpalte
Next iSpalte
End If
' Daten umsortieren und in Hilfstabelle abfüllen
For iZeile = 1 To WS1.Range("A65536").End(xlUp).Row
WS2.Cells(WS2.Cells(65536, WS1.Cells(iZeile, 1)).End(xlUp).Row + 1, WS1.Cells(iZeile, 1)) = WS1.Cells(iZeile, 2)
Next iZeile
' Überfüssige Spalten löschen
For iSpalte = 200 To 1 Step -1
LetzteZeile = WS2.Cells(65536, iSpalte).End(xlUp).Row
If WS2.Cells(2, iSpalte) = "" Or _
WorksheetFunction.CountIf(WS2.Range(WS2.Cells(LetzteZeile, iSpalte), WS2.Cells(2, iSpalte)), WS2.Cells(2, iSpalte)) = LetzteZeile - 1 Then _
Columns(iSpalte).Delete
Next iSpalte
' Diagramm erzeugen
Set Diagramm = Charts.Add
With Diagramm
.SetSourceData Source:=WS2.UsedRange
.Location Where:=xlLocationAsNewSheet
End With
Application.ScreenUpdating = True
End Sub


Function WSVorhanden(strWS As String) As Boolean
Dim WS As Worksheet
' Funktion zur Prüfung ob Tabelle vorhanden
For Each WS In ActiveWorkbook.Worksheets
If WS.Name = strWS Then
WSVorhanden = True
Exit Function
End If
Next WS
End Function

AW: Grafik aus Zahlenreihen erstellen

21.12.2004 09:19:39

Simon

Hallo Chris,
vielen Dank für die schnelle und vor allem funktionierende Antwort.
Das umsortieren in die Hilfstabelle ist genau der richtige Ansatz um auch noch andere Probleme bei mir zu lösen. "ich werde noch zum Excel-Junkie"
Gruß Simon
@Volker: Ich habe mich leider nicht verschrieben, ich muss wirklich ziemlich viele Daten auswerten.

Beliebteste Forumthreads (12 Monate)

Grafik aus Zahlenreihen erstellen

Forumthread: Grafik aus Zahlenreihen erstellen

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Grafik aus Zahlenreihen erstellen

Forumthread: Grafik aus Zahlenreihen erstellen

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread