Überschneidungen beim Datum anzeigen

Forumthread: Überschneidungen beim Datum anzeigen

12.02.2005 20:37:38

JensW

Hallo
ich habe folgendes Problem das vielleicht schon jamand bereits gelöst hat:
Ich arbeite mit einer Tabelle die wie folgt aufgebaut ist

_____A_________B_______C_______D__ E F G H
1 Aufenthalt von | Aufenthalt bis | Zimmer Nr. | Name |
2 21.02.2003 | 26.03.2003 | 16 | Fr.Schmidt| txt .. .. ..
3 14.05.2003 | 17.05.2003 | 15 | Hr.Bauer | txt .. ....
4 15.05.2003 | 28.05.2003 | 16 | Fr.Müller | txt .. ....
5 15.06.2003 | 16.06.2003 | 11 | Hr.Nordman| txt .. ...
Es geht mir nun darum, Überschneidungen der einzelnen Aufenthaltszeiten zu markieren. In diesem Fall sollte die Zeile 3 und 4 kenntlich gemacht werden da eine Überschneidung vorliegt. In einem weiteren Schritt soll die Überschneidung nur dann angezeigt werden, wenn sich die Personen im gleichen Zimmer aufgehalten haben.
Bis jetzt habe ich die Auswertung immer von "Hand" gemacht, da ich keine Ahnung habe wie ich mit Monaten rechnen soll.Nun ist die Tabelle aber zu groß geworden. Die gesamte Tabelle umfasst 100 Personen mit 20 weiteren Punkten oben angedeutet mit E F G H I ...
Wie die überschneidungen kenntlich gemacht werden ( ob mit einem X wie ich es bisher versucht habe oder farbig unterlegt) ist total egal.
Über Hilfe freut sich
Jens ausm Schwabenland und zwar riesig

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Überschneidungen beim Datum anzeigen

12.02.2005 20:52:48

Josef

Hallo Jens!
Vielleicht so.

Tabelle2

	A	B	C	D	E	F
1	Aufenthalt von	Aufenthalt bis	Zimmer
2	21.02.2003	26.03.2003	15	Fr.Schmidt
3	14.05.2003	17.05.2003	16	Hr.Bauer		Doppelbelegung!
4	15.05.2003	28.05.2003	16	Fr.Müller		Doppelbelegung!
5	15.06.2003	16.06.2003	11	Hr.Nordman
6	20.03.2003	26.03.2003	14	Fr. Weis

Formeln der Tabelle

F2 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B2)*($B$2:$B$5>=A2)*($C$2:$C$5=C2))>1;"Doppelbelegung!";"")
F3 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B3)*($B$2:$B$5>=A3)*($C$2:$C$5=C3))>1;"Doppelbelegung!";"")
F4 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B4)*($B$2:$B$5>=A4)*($C$2:$C$5=C4))>1;"Doppelbelegung!";"")
F5 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B5)*($B$2:$B$5>=A5)*($C$2:$C$5=C5))>1;"Doppelbelegung!";"")
F6 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B6)*($B$2:$B$5>=A6)*($C$2:$C$5=C6))>1;"Doppelbelegung!";"")

Bedingte Formatierungen der Tabelle

Zelle	Nr.: / Bedingung	Format
A2	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B2)($B$2:$B$6>=$A2)($C$2:$C$6=$C2))>1	Abc
B2	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B2)($B$2:$B$6>=$A2)($C$2:$C$6=$C2))>1	Abc
A3	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B3)($B$2:$B$6>=$A3)($C$2:$C$6=$C3))>1	Abc
B3	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B3)($B$2:$B$6>=$A3)($C$2:$C$6=$C3))>1	Abc
A4	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B4)($B$2:$B$6>=$A4)($C$2:$C$6=$C4))>1	Abc
B4	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B4)($B$2:$B$6>=$A4)($C$2:$C$6=$C4))>1	Abc
A5	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B5)($B$2:$B$6>=$A5)($C$2:$C$6=$C5))>1	Abc
B5	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B5)($B$2:$B$6>=$A5)($C$2:$C$6=$C5))>1	Abc
A6	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B6)($B$2:$B$6>=$A6)($C$2:$C$6=$C6))>1	Abc
B6	1. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B6)($B$2:$B$6>=$A6)($C$2:$C$6=$C6))>1	Abc

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Sepp
P.S.: Rückmeldung nicht vergessen!

AW: Überschneidungen beim Datum anzeigen

12.02.2005 20:58:16

Josef

Hallo nochmal!
Kleiner Fehler in der Zellformel.

Tabelle2

	A	B	C	D	E	F
1	Aufenthalt von	Aufenthalt bis	Zimmer
2	21.02.2003	26.03.2003	14	Fr.Schmidt		Doppelbelegung!
3	14.05.2003	17.05.2003	15	Hr.Bauer
4	15.05.2003	28.05.2003	12	Fr.Müller
5	15.06.2003	16.06.2003	11	Hr.Nordman
6	20.03.2003	26.03.2003	14	Fr. Weis		Doppelbelegung!

Formeln der Tabelle

F2 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B2)*($B$2:$B$6>=A2)*($C$2:$C$6=C2))>1;"Doppelbelegung!";"")
F3 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B3)*($B$2:$B$6>=A3)*($C$2:$C$6=C3))>1;"Doppelbelegung!";"")
F4 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B4)*($B$2:$B$6>=A4)*($C$2:$C$6=C4))>1;"Doppelbelegung!";"")
F5 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B5)*($B$2:$B$6>=A5)*($C$2:$C$6=C5))>1;"Doppelbelegung!";"")
F6 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B6)*($B$2:$B$6>=A6)*($C$2:$C$6=C6))>1;"Doppelbelegung!";"")

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß Sepp
P.S.: Rückmeldung nicht vergessen!

AW: Überschneidungen beim Datum anzeigen

Ulf

Können auch mehrere Zeilen zwischen Überschneidungen liegen, oder ist es immer
die nächste Zeile?
Ulf

AW: Überschneidungen beim Datum anzeigen

12.02.2005 21:34:30

JensW

Man seid ihr schnell!
Vielen Dank ich versuche es gerade auf meine Tabelle zuzuschneiden.
@Ulff: Es können auch mehrere Zeilen dazwischen liegen. Im Normalfall liegen auch so 5 bis 8 dazwischen.
@Josef Ehrensberger: vielen Dank! probiere es gerade aus. Als Anfänger dauert das leider ein wenig.

@Ulff

12.02.2005 21:40:26

JensW

Es können auch mehrere Zeilen dazwischen liegen. Normalerweise so 5-8
Gruß Jens
Und Danke

AW: @Ulff

Ulf

Die Lösung von Sepp ist doch ok.
Ulf

Die Lösung ist sehr gut.

12.02.2005 21:47:53

JensW

Die Lösung von Josef Ehrensberger ist wirklich gut ich wollte nur höflich sein und alle Fragen beantworten wenn man mir schon so nett weiter hilft.
Also nochmals meinen Dank an euch
Ciao Jens

Infobox / Tutorial

Überschneidungen beim Datum anzeigen in Excel

Schritt-für-Schritt-Anleitung
Häufige Fehler und Lösungen
Alternative Methoden
Praktische Beispiele
Tipps für Profis
FAQ: Häufige Fragen

Schritt-für-Schritt-Anleitung

Erstelle deine Tabelle: Beginne mit einer Excel-Tabelle, die mindestens die Spalten "Aufenthalt von", "Aufenthalt bis", "Zimmer Nr." und "Name" enthält.
Formel zur Erkennung von Überschneidungen: In der ersten Zelle der Spalte für die Anzeige von Überschneidungen (z.B. F2) fügst du die folgende Formel ein:
```
=WENN(SUMMENPRODUKT(($A$2:$A$100<=B2)*($B$2:$B$100>=A2)*($C$2:$C$100=C2))>1;"Doppelbelegung!";"")
```
Hierbei wird angenommen, dass deine Daten in den Zeilen 2 bis 100 stehen. Passe den Bereich entsprechend deiner Daten an.
Ziehen der Formel: Ziehe die Formel für alle relevanten Zeilen nach unten, um die Überschneidungen für alle Aufenthalte zu überprüfen.
Bedingte Formatierung: Um die Überschneidungen visuell hervorzuheben, gehe zu "Bedingte Formatierung" und füge eine neue Regel hinzu, die die Zellen mit "Doppelbelegung!" rot einfärbt.
Überprüfen: Stelle sicher, dass die Formel für alle Zeilen korrekt funktioniert.

Häufige Fehler und Lösungen

Fehler: Keine Anzeige von Überschneidungen: Prüfe, ob die Zellbezüge in der Formel korrekt sind. Achte darauf, dass die Bereiche ($A$2:$A$100, $B$2:$B$100, $C$2:$C$100) den tatsächlichen Bereich deiner Daten abdecken.
Fehler: Falsche Zimmernummern: Stelle sicher, dass die Zimmernummern in der Spalte "Zimmer Nr." übereinstimmen, da die Formel nur Überschneidungen in gleichen Zimmern anzeigt.

Alternative Methoden

Pivot-Tabellen: Eine Pivot-Tabelle kann helfen, die Daten nach Zimmern und Aufenthaltszeiten zu gruppieren, um Überschneidungen leichter zu erkennen.
Diagramme: Erstelle Diagramme, um visuelle Überschneidungen darzustellen. Dies kann hilfreich sein, wenn du viele Daten hast.

Praktische Beispiele

Hier ist ein Beispiel, wie deine Tabelle aussehen könnte, nachdem die Überschneidungen angezeigt werden:

Aufenthalt von	Aufenthalt bis	Zimmer Nr.	Name	Überschneidung
21.02.2003	26.03.2003	16	Fr. Schmidt
14.05.2003	17.05.2003	15	Hr. Bauer	Doppelbelegung!
15.05.2003	28.05.2003	16	Fr. Müller	Doppelbelegung!
15.06.2003	16.06.2003	11	Hr. Nordman

Tipps für Profis

Nutzung von Datenvalidierung: Verwende Datenvalidierung, um sicherzustellen, dass nur gültige Daten in die Tabelle eingegeben werden. Dies kann die Wahrscheinlichkeit von Fehlern verringern.
Makros: Falls du oft mit ähnlichen Daten arbeitest, könnte es sinnvoll sein, ein Makro zu erstellen, das diesen Prozess automatisiert.

FAQ: Häufige Fragen

1. Wie viele Überschneidungen kann ich mit dieser Methode finden?
Mit der vorgestellten Methode kannst du beliebig viele Überschneidungen in deiner Excel-Tabelle anzeigen, solange du die Formel entsprechend anpasst.

2. Funktioniert dies in allen Excel-Versionen?
Ja, die beschriebenen Formeln und Funktionen sind in den meisten modernen Excel-Versionen verfügbar, einschließlich Excel 2010 und neuer.

3. Kann ich die Formel auch für andere Datentypen verwenden?
Ja, du kannst die Logik der Formel anpassen, um auch andere Datentypen zu überprüfen, solange die Bedingungen entsprechend angepasst werden.

Beliebteste Forumthreads (12 Monate)

Überschneidungen beim Datum anzeigen

Forumthread: Überschneidungen beim Datum anzeigen

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Überschneidungen beim Datum anzeigen in Excel

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

Überschneidungen beim Datum anzeigen

Forumthread: Überschneidungen beim Datum anzeigen

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Überschneidungen beim Datum anzeigen in Excel

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread