Button soll nicht mit Hintergrund scrollen

Forumthread: Button soll nicht mit Hintergrund scrollen

30.06.2005 08:45:15

Ulf

Hallo,
ich habe Tabellen, in denen sich Buttons befinden, denen wiederum über Module Macros zugewiesen sind. Da die Tabellen z.T. sehr lang sind, möchte ich, dass sich diese Buttons an einem bestimmten Bereich des Programmfensters befinden ohne beim Scrollen durch die Tabelle mitverschoben zu werden, damit nach diesen Buttons nicht in der ganzen Tabelle gesucht werden muss.
Kurz:
Buttons fix, kein Scrollen (z.B. immer rechts oben im Fenster)
Rest (Werte, Text, Hintergrund) soll scrollbar sein
Weiss leider nur, wie das für Html realisierbar ist.
Besten Dank für die Hilfe
Ulf

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Button soll nicht mit Hintergrund scrollen

30.06.2005 09:50:59

Klaus

Moin Ulf,
ich umgehe dieses Problem bisher, habe meine Buttons immer ganz oben im Dokument und fixiere die ersten paar Zeilen. Mich interessiert jetzt aber auch, ob es ein "noscroll" für Buttons gibt :) daher Frage noch offen.
Gruß,
Klaus

AW: Button soll nicht mit Hintergrund scrollen

30.06.2005 13:09:02

Ralf

...lach...
da sind wir ja schon 3, die das interessiert...
Hi Ulf und Klaus,
meines Wissens nach ist bei Objekten aus der Toolbox dieses Verhalten nicht zu beeinflussen. Als Alternative käme noch ein in der VBE erstelltes Formular mit integrierten Buttons in Frage, da ieses Objekt nicht mit dem Tabellenblatt verbunden ist.
Ciao, Ralf

AW: Button soll nicht mit Hintergrund scrollen

30.06.2005 17:59:09

Nepumuk

Hi,
ich würde da eine frei schwebende Symbolleiste verwenden. Mal ein kleines Beispiel.
Folgenden Code in das Klassenmodul "DieseArbeitsmappe":
Option Explicit

Private Sub Workbook_Activate()
    Call prcShowBar(ActiveSheet.CodeName = "Tabelle1")
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    With ThisWorkbook
        If Not .Saved Then
            Select Case MsgBox("Änderungen speichern?", 35, "Abfrage")
                Case 2
                    Cancel = True
                    Exit Sub
                Case 6: .Save
                Case 7: .Saved = True
            End Select
        End If
    End With
    Call prcDeleteBar
End Sub

Private Sub Workbook_Open()
    Call prcCreateBar
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    Call prcShowBar(ActiveSheet.CodeName = "Tabelle1")
End Sub

Folgenden Code in ein Standardmodul:
Option Explicit
Option Private Module

Private Const BAR_NAME = "Ulf privat"

Private cmbBar As CommandBar

Public Sub prcCreateBar()
    Dim cmbButton As CommandBarButton
    Call prcDeleteBar
    Set cmbBar = Application.CommandBars.Add(Name:=BAR_NAME, _
        Position:=msoBarFloating, Temporary:=True)
    Set cmbButton = cmbBar.Controls.Add(Type:=msoControlButton)
    With cmbButton
        .Caption = "TestButton"
        .FaceId = 59
        .OnAction = "TestMakro"
        .Style = msoButtonIconAndCaption
    End With
    Set cmbButton = Nothing
    With cmbBar
        .Left = 100
        .Top = 200
        .Protection = msoBarNoChangeVisible + msoBarNoCustomize + _
            msoBarNoMove + msoBarNoResize
    End With
End Sub

Public Sub prcDeleteBar()
    If Not cmbBar Is Nothing Then
        cmbBar.Delete
    Else
        For Each cmbBar In Application.CommandBars
            If cmbBar.Name = BAR_NAME Then cmbBar.Delete
        Next
    End If
    Set cmbBar = Nothing
End Sub

Public Sub prcShowBar(bolVisible As Boolean)
    If cmbBar Is Nothing Then Call prcCreateBar
    cmbBar.Visible = bolVisible
End Sub

Private Sub TestMakro()
    MsgBox "Hallo :-)", 64, "Info"
End Sub

Was ihr mit Symbolleisten alles anstellen könnt, findet ihr hier:
http://www.online-excel.de/excel/grusel_vba.php?f=2
Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Button soll nicht mit Hintergrund scrollen

Forumthread: Button soll nicht mit Hintergrund scrollen

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread