Zeilen mit bestimmten Datum auswählen

Robert · 2005-07-17T14:20:25+00:00

Hallo Ich arbeite mit einer Tabelle, die in Spalte B ein Datum eingetragen hat. Ich muss diese Daten einmal im Monat automatisch in eine andere Tabelle kopieren. Mein Problem ist also, wie kann man (mit VBA), vielleicht nach Eingabe des Monats über Inputbox, alle Zeilen makrieren, die in Spalte B den definierten Monat haben? Das Datum ist tt.mm.jjjj. Ich brauche also für "mm" eine Variabel, die mir hilft die richten Zeilen zu finden... Kann mir da jemand helfen? mfg Robert

Hallo Robert,
wie gefällt Dir das?


Sub Robert()
Dim c As Range, ErgBereich As Range, _
Mon As String, _
laR As Long, _
check As Boolean
Mon = InputBox(vbCr & vbCr & vbCr & "Gesuchter Monat:")
If Mon = "" Then check = True
If IsNumeric(Mon) Then
If Mon < 1 Or Mon > 12 Then check = True
Else
check = True
End If
If check = True Then
MsgBox "Keine oder falsche Eingabe !" & vbCr & vbCr & _
"Makro-Abbruch !", vbOKOnly + vbCritical, _
"Dezenter Hinweis für " & Application.UserName & ":"
Exit Sub
End If
Application.ScreenUpdating = False
laR = Cells(Rows.Count, 2).End(xlUp).Row
For Each c In Range("B1:B" & laR)
If IsDate(c.Text) Then
If Month(CDate(c.Text)) = Mon Then
Set ErgBereich = Rows(c.Row)
Exit For
End If
End If
Next c
If ErgBereich Is Nothing Then
MsgBox "Nichts gefunden !", vbOKOnly + vbInformation, _
"Dezenter Hinweis für " & Application.UserName & ":"
Else
For Each c In Range("B1:B" & laR)
If IsDate(c.Text) Then
If Month(CDate(c.Text)) = Mon Then
Set ErgBereich = Application.Union(ErgBereich, Rows(c.Row))
End If
End If
Next c
ErgBereich.Select
Set ErgBereich = Nothing
End If
Application.ScreenUpdating = True
End Sub

Viel Erfolg wünscht
WernerB.
P.S.: Dieses Forum lebt auch von den Rückmeldungen der Fragesteller an die Antworter !

Hallo Reinhard,
Deine Datei lässt sich leider nicht downloaden.
Ungeachtet dessen: Nachstehend noch mal beide Alternativen.
Bei mir (Excal XP) führt im Makro "Reinhard" eine nichtnumerische Eingabe ("xyz") oder ein Abbruch immer zu einem Makro-Fehler.
Ist das bei Dir nicht so?


Sub Werner()
Dim Mon As String, _
check As Boolean
Mon = InputBox(vbCr & vbCr & vbCr & "Gesuchter Monat:")
If IsNumeric(Mon) Then
If Mon < 1 Or Mon > 12 Then check = True
Else
check = True
End If
If check = True Then
MsgBox "Keine oder falsche Eingabe !" & vbCr & vbCr & _
"Makro-Abbruch !", vbOKOnly + vbCritical, _
"Dezenter Hinweis für " & Application.UserName & ":"
Exit Sub
Else
MsgBox "die Monatsnummer ist i.O. !"
End If
End Sub


Sub Reinhard()
Dim Mon As String, _
check As Boolean
Mon = InputBox(vbCr & vbCr & vbCr & "Gesuchter Monat:")
If IsNumeric(Mon) And Mon >= 1 And Mon <= 12 Then check = True
If check = False Then
MsgBox "Keine oder falsche Eingabe !" & vbCr & vbCr & _
"Makro-Abbruch !", vbOKOnly + vbCritical, _
"Dezenter Hinweis für " & Application.UserName & ":"
Exit Sub
Else
MsgBox "die Monatsnummer ist i.O. !"
End If
End Sub

Gruß
Werner

Zeilen mit bestimmten Datum auswählen

Forumthread: Zeilen mit bestimmten Datum auswählen

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Infobox / Tutorial