AW: Alle VBA-Codes der aktiven Mappe löschen !!!
14.11.2005 10:49:55
Heiko
Hallo Harry,
dazu gibt es bestimmt hunderte Einträge in der Recherche, z.B. diesen hier von mir.
Beim nächsten mal vielleicht zuerst mal in die Recherche schauen ;-)
Function CodeKomplettLoeschen(wkbMappe As Workbook)
' Aufruf z.B. so:
' CodeKomplettLoeschen ThisWorkbook
Dim vbc As Object
On Error GoTo Errorhandler
With wkbMappe.VBProject
For Each vbc In .VBComponents
Select Case vbc.Type
Case 1 To 3
.VBComponents.Remove .VBComponents(vbc.Name)
Case 100
With .VBComponents(vbc.Name).CodeModule
.DeleteLines 1, .CountOfLines
End With
Case Else
MsgBox "Unbekannter VBA Type !", vbCritical
End Select
Next vbc
End With
Exit Function
' Bei Fehlernummer 1004, diese Meldung ausgeben.
Errorhandler:
If Err.Number = 1004 Then
MsgBox "Das Löschen des VBA Codes ist fehlgeschlagen!" & vbCr & _
"Bitte überprüfen Sie folgende Einstellung! " & vbCr & _
"EXTRAS -> MAKRO -> SICHERHEIT -> Vertrauenwürdige Quellen." & vbCr & _
"'Zugriff auf Visual Basic Projekt vertrauen' muss aktiviert sein! ", vbCritical, _
" Meldung vom Funktion CodeKomplettLoeschen"
Else
MsgBox "Err.Number = " & Err.Number & ". " & Err.Description, vbCritical
End If
End Function
Gruß Heiko
PS: Rückmeldung wäre nett !