Laufschrift in Userform

Heinz · 2005-11-28T09:52:38+00:00

Hallo Excelfans! Möchte in meinem Userform eine Laufschrift einbauen. Dies soll so aussehen dass nach dem Aufruf des userform einfach ein bstimmter Text immer wieder von rechts nach links durchläuft.(so wie z.b im Fernsehen die Börsenkurse) Geht das ? Grüße Heinz

Hallo Heinz,
mein Vorschlag:
In eine Userform eine Label "Label1"
Der Code:


Option Explicit
Const LaufText = "Guten Morgen, Heinz"
Private Sub UserForm_Initialize()
With Label1
.Caption = LaufText
.AutoSize = True
.Left = Me.Width + 10
End With
End Sub
Private Sub UserForm_Activate()
Const Speed = 0.01
Dim t1 As Single
On Error GoTo geschlossen
t1 = Timer + Speed
Do While Me.Visible = True
DoEvents
'i = i + 1
'je kleiner, desto schneller die Geschwindigkeit
If Timer > t1 Then
'i = 0
t1 = Timer + Speed
With Label1
.Left = .Left - 1
If .Left + .Width < 0 Then
.Left = Me.Width + 10
End If
End With
End If
Loop
geschlossen:
End Sub
'Schließen-Knopf
Private Sub CommandButton1_Click()
Unload Me
End Sub

Der Code von Nepumuk ist wahrscheinlich besser, v.a. weil der Code nicht in einer Endlosschleife läuft, bis die UF entladen wird, aber ich hab mir jetzt solche Mühe gegeben... ;-)
Gruß Matthias

Hallo,
hier noch eine Variante ohne externe Datei:

' **********************************************************************
' Modul: UserForm1 Typ: Userform
' **********************************************************************

Option Explicit

Private Declare Sub Sleep Lib "kernel32.dll" ( _
    ByVal dwMilliseconds As Long)

Private blnLoad As Boolean

Private Sub UserForm_Activate()
    WebBrowser1.Navigate2 "about:blank"
    Do While blnLoad
        DoEvents
        Sleep 10
    Loop
    WebBrowser1.Document.body.innerHTML = _
        "<marquee>Das ist der Text der durchlaufen soll</marquee>"
End Sub

Private Sub WebBrowser1_BeforeNavigate2(ByVal pDisp As Object, _
        URL As Variant, Flags As Variant, TargetFrameName As Variant, _
        PostData As Variant, Headers As Variant, Cancel As Boolean)
    blnLoad = True
End Sub

Private Sub WebBrowser1_DocumentComplete(ByVal pDisp As Object, URL As Variant)
    blnLoad = False
End Sub

Private Sub WebBrowser1_NavigateComplete2(ByVal pDisp As Object, URL As Variant)
    With WebBrowser1.Document.body
        .Scroll = "no"
        .Style.Border = "none"
    End With
End Sub

Gruß
Nepumuk

Forumthread: Laufschrift in Userform

26
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Laufschrift in Userform

Forumthread: Laufschrift in Userform

26 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

26
Beiträge zum Forumthread

Beiträge zu diesem Forumthread