bestimmten Bereich der aktiven Zeile löschen

Forumthread: bestimmten Bereich der aktiven Zeile löschen

01.05.2006 23:44:50

tco99

Hallo zusammen,
ich habe folgenden Code gebastelt:


Sub BereichDerZelleLöschen()
ActiveRows.Range("A$;U$").Select
Selection.ClearContents
Range("A1").Select
End Sub

Ich wollte, dass immer die Inhalte der Zellen A bis U der aktiven Zeile gelöscht werden. Leider ist der Code falsch. Ich denke, es liegt an den $-Zeichen. Ich hatte mir gedacht, dass das $-Zeichen als Platzhalter dienen kann. Vielen Dank für die Hilfe.
Erdogan

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: bestimmten Bereich der aktiven Zeile löschen

01.05.2006 23:52:38

PeterW

Hallo Erdogan,
versuch es mal so:


Sub BereichDerZelleLöschen()
Range("A" & ActiveCell.Row & ":U" & ActiveCell.Row).ClearContents
Range("A1").Select
End Sub

Gruß
Peter

AW: bestimmten Bereich der aktiven Zeile löschen

01.05.2006 23:59:51

tco99

Hallo Peter,
wie oft hast du mir jetzt schon geholfen? :-)
Herzlichen Dank dafür!
Habe diesen Code gebastelt bekommen,
wenn es einem um die ganze Zeile und
nicht einen bestimmten Bereich der Zeile geht:


Sub LöschtInhalteDerAktivenZeile()
Rows(ActiveCell.Row).Select
'markiert die Zeile, in der der Cursor steht
Selection.ClearContents
'löscht den Inhalt des markierten Bereichs
Range("A1").Select
'setzt den Cursor in die Zelle A1
End Sub

Mir reicht dieser Code leider nicht,
bin daher für deinen Code sehr dankbar!
Gruß,
Erdogan

AW: bestimmten Bereich der aktiven Zeile löschen

02.05.2006 08:03:37

Erich

Hallo Erdogan,
noch was zum Spielen:

Option Explicit
Sub LeertAktiveZeile()
Rows(ActiveCell.Row).ClearContents
End Sub
Sub LeertSpaltenCDderAktivenZeile()
Rows(ActiveCell.Row).Columns("C:D").ClearContents
End Sub
Sub LeertZeilenEinesMarkiertenBereichs()
Selection.EntireRow.ClearContents
End Sub
Sub LeertSpaltenCDderZeilenEinesMarkiertenBereichs()
Selection.EntireRow.Columns("C:D").ClearContents
End Sub
Sub LeertZeilenInZeilenAllerMarkiertenBereiche()
Dim rg As Range
For Each rg In Selection.Areas
rg.EntireRow.ClearContents
Next rg
End Sub
Sub LeertSpaltenCDderZeilenAllerMarkiertenBereiche()
Dim rg As Range
For Each rg In Selection.Areas
rg.EntireRow.Columns("C:D").ClearContents
Next rg
End Sub

Grüße von Erich aus Kamp-Lintfort

AW: bestimmten Bereich der aktiven Zeile löschen

03.05.2006 16:41:10

tco99

Hallo Erich,
vielen Dank für deine Antwort!
Entschuldige die späte Reaktion,
habe sie erst jetzt gelesen.
MfG aus Oberhausen,
Erdogan

Danke für Rückmeldung - und noch ...

03.05.2006 17:14:49

Erich

Hallo Erdogan,
... ein paar weitere (und teilweise kürzere, bessere) Möglichkeiten:

Sub LeertAktiveZeile()
Rows(ActiveCell.Row).ClearContents
'oder
ActiveCell.EntireRow.ClearContents
End Sub
Sub LeertSpaltenCDderAktivenZeile()
Columns("C:D").Rows(ActiveCell.Row).ClearContents
'oder
[C:D].Rows(ActiveCell.Row).ClearContents
'oder
Rows(ActiveCell.Row).Columns("C:D").ClearContents
'oder
ActiveCell.EntireRow.Columns("C:D").ClearContents
'oder
Intersect(Rows(ActiveCell.Row), [C:D]).ClearContents
'oder
Intersect(ActiveCell.EntireRow, [C:D]).ClearContents
End Sub
' Subs funzen auch bei Mehrfachmarkierung (Areas-Schleife ist unnötig)
Sub LeertZeilenAllerMarkiertenBereiche()
Selection.EntireRow.ClearContents
End Sub
Sub LeertSpaltenCDderZeilenAllerMarkiertenBereiche()
Intersect(Selection.EntireRow, Columns("C:D")).ClearContents
'oder
Intersect(Selection.EntireRow, [C:D]).ClearContents
End Sub
Sub LeertSpaltenABDderZeilenAllerMarkiertenBereiche()
Intersect(Selection.EntireRow, Union(Columns("A:B"), Columns("D"))).ClearContents
'oder
Intersect(Selection.EntireRow, [A:B,D:D]).ClearContents
End Sub

Grüße von Erich aus Kamp-Lintfort

Vielen Dank!

03.05.2006 18:21:04

Erdogan

...

Beliebteste Forumthreads (12 Monate)

bestimmten Bereich der aktiven Zeile löschen

Forumthread: bestimmten Bereich der aktiven Zeile löschen

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread