Zeilen aus Textdatei löschen

Forumthread: Zeilen aus Textdatei löschen

14.05.2006 09:17:51

andS

Hallo,
wie lösche ich Zeilen aus einer Textdatei? Ich möchte alle Zeilen, die zwischen "# Write Values" und "# End Write" stehen, aus meiner Textdatei löschen.
Wie mache ich das?
Danke für jede Hilfe!
Grüße Andi

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zeilen aus Textdatei löschen

14.05.2006 10:27:38

Josef
Danke!!!

14.05.2006 10:38:25

andS
Noch eine Frage...

14.05.2006 10:46:25

andS
AW: Noch eine Frage...

14.05.2006 11:00:14

Josef
Genial!

14.05.2006 11:05:58

andS

AW: Zeilen aus Textdatei löschen

14.05.2006 10:27:38

Josef

Hallo Andi!
Probier mal!

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Sub RemoveLinesFromTextfile()
Dim strFile As String, strTempFile As String, strPath As String
Dim FF1 As Integer
Dim FF2 As Integer
Dim strLine As String
Dim bWrite As Boolean, bMark As Boolean

On Error GoTo err_Handler

strPath = "F:\Temp\" ' Pfad zur Datei - Anpassen!

strFile = "test.txt" ' Textdatei - Anpassen!

If Right(strPath, 1) <> "\" Then strPath = strPath & "\"

strTempFile = strPath & "Temp_" & strFile
strFile = strPath & strFile

FileCopy strFile, strTempFile

bWrite = True

FF1 = FreeFile()
Open strTempFile For Input As #FF1
FF2 = FreeFile()
Open strFile For Output As #FF2
Do While Not EOF(FF1)
  Line Input #FF1, strLine

  bMark = True

  If strLine = "# Write Values" Then bWrite = False

  If strLine = "# End Write" Then bWrite = True: bMark = False

  If bWrite And bMark Then Print #FF2, strLine

Loop
Close #FF2
Close #FF1

Kill strTempFile

MsgBox "Der Vorgang wurde erfolgreich abgeschlossen ;-)", _
  vbInformation, "Fertig"
Exit Sub

err_Handler:
MsgBox Err.Description, vbCritical, "Fehler"
End Sub

'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

Danke!!!

14.05.2006 10:38:25

andS

Hi,
danke für die schnelle und super Hilfe!!!
Einfach genial!
Grüße Andi

Noch eine Frage...

14.05.2006 10:46:25

andS

...wie kann ich verhindern, dass auch "# Write Values" und "# End Write" gelöscht wird?
Brauche das um wieder zu schreiben, bzw. erneut zu löschen.
Es wäre sehr nett, wenn du mir nochmals helfen könntest.
Grüße Andi

AW: Noch eine Frage...

14.05.2006 11:00:14

Josef

Hallo Andi!
Dann so.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Sub RemoveLinesFromTextfile()
Dim strFile As String, strTempFile As String, strPath As String
Dim FF1 As Integer
Dim FF2 As Integer
Dim strLine As String
Dim bWrite As Boolean, bMark As Boolean

On Error GoTo err_Handler

strPath = "F:\Temp\" ' Pfad zur Datei - Anpassen!

strFile = "test.txt" ' Textdatei - Anpassen!

If Right(strPath, 1) <> "\" Then strPath = strPath & "\"

strTempFile = strPath & "Temp_" & strFile
strFile = strPath & strFile

FileCopy strFile, strTempFile

bWrite = True
bMark = True

FF1 = FreeFile()
Open strTempFile For Input As #FF1
FF2 = FreeFile()
Open strFile For Output As #FF2
Do While Not EOF(FF1)
  Line Input #FF1, strLine

  If strLine = "# Write Values" Then bMark = False

  If strLine = "# End Write" Then bWrite = True: bMark = True

  If bWrite Then Print #FF2, strLine
  bWrite = bMark

Loop
Close #FF2
Close #FF1

Kill strTempFile

MsgBox "Der Vorgang wurde erfolgreich abgeschlossen ;-)", _
  vbInformation, "Fertig"
Exit Sub

err_Handler:
MsgBox Err.Description, vbCritical, "Fehler"
End Sub

'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

Genial!

14.05.2006 11:05:58

andS

Danke! Super Hilfe!!
Grüße Andi

Beliebteste Forumthreads (12 Monate)

Forumthread: Zeilen aus Textdatei löschen

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread