Werte von einer Tabelle in eine andere kopieren un

Forumthread: Werte von einer Tabelle in eine andere kopieren un

04.06.2006 13:03:38

einer

Ich möchte Summen- und Saldenlisten in eine Tabelle zur Kostenstellen-berechnung kopieren.
Die Zieltabelle hat alle Kontonummern in einer Spalte. In die leere Spalte rechts daneben sollen Werte aus der SUSA-Tabelle kopiert werden.
Die SUSA-Tabelle hat nur einige Kontonummern mit dazugehörigen Werten in der rechten Spalte.
Ich möchte nun diese Werte in die Zieltabelle kopieren und sie automatisch den richtigen Kontonummern zuordnen.

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Werte von einer Tabelle in eine andere kopiere

04.06.2006 13:12:56

einer

Hallo W-Uhlmann!
Wie sind den die Tabellen aufgebaut? Beispiel?

'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

AW: Werte von einer Tabelle in eine andere kopiere

04.06.2006 13:18:07

einer

Die Zieltabelle hat u.a. eine Spalte für die Kontonummern, rechts daneben eine für die Kontobezeichnung und danach eine leere Spalte für die Werte.
Die SUSA-Tabelle kann ich auf nur zwei Spalten reduzieren: Eine für die Kontonummern und eine für die Werte.
Gruß
Wilfried Uhlmann

AW: Werte von einer Tabelle in eine andere kopiere

04.06.2006 13:57:13

einer

Hallo Wilfried!
Ich nehme mal an, das sich in Zeile eins die Spaltenüberschriften befinden und
ab "A2" die daten stehen.
Dann probier mal diesen Code.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Sub GetValues()
Dim strFile As String, strSheet As String
Dim varValues As Variant
Dim lngR As Long
Dim rng As Range

strFile = Application.GetOpenFilename("Excel Dateien (*.xls; *.xlt; *.xla)," & _
  "*.xls; *.xlt; *.xla")

If strFile = "Falsch" Then Exit Sub

strSheet = "Tabelle1" ' Tabellenname - Anpassen!

With ExcelTable(strFile, strSheet, "A:B")
  varValues = .GetRows
  .Close
End With

For lngR = 0 To UBound(varValues, 2)
  If Not IsEmpty(varValues(0, lngR)) Then
    Set rng = Range("A:A").Find(varValues(0, lngR), lookat:=xlWhole)
    If Not rng Is Nothing Then
      rng.Offset(0, 2) = varValues(1, lngR)
    End If
  End If
Next

Set rng = Nothing

End Sub

Public Function ExcelTable(ByRef Path As String, ByRef Table As String, ByRef SourceRange As String) As Object
Dim SQL As String
Dim Con As String

SQL = "select * from [" & Table & "$" & SourceRange & "]"
Con = "Provider=Microsoft.Jet.OLEDB.4.0;" _
  & "Extended Properties=Excel 8.0;" _
  & "Data Source=" & Path & ";"
Set ExcelTable = CreateObject("ADODB.Recordset")
ExcelTable.Open SQL, Con, 1, 3
End Function

'******************************
'* Gruß Sepp
'*
'* Rückmeldung wäre nett!
'******************************

Beliebteste Forumthreads (12 Monate)

Werte von einer Tabelle in eine andere kopieren un

Forumthread: Werte von einer Tabelle in eine andere kopieren un

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Werte von einer Tabelle in eine andere kopieren un

Forumthread: Werte von einer Tabelle in eine andere kopieren un

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread