Zeile transponieren und sortieren

Forumthread: Zeile transponieren und sortieren

27.06.2006 22:02:11

Georg

Hallo,
folgende Situation, ich habe in einer Zeile Werte, denen ich mittels der "RANG"-Funktion einen Position zugeordnet habe. Jetzt möchte ich diese Zeile ganz gerne Sortieren, so dass die Ränge von klein nach groß sortiert sind und in einer Spalte von oben nach unten stehen! Freu mich auf jede Hilfe, freundliche Grüße, Schorsch

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zeile transponieren und sortieren

27.06.2006 22:08:48

Josef

Hallo Georg!
Meinst du so?

Tabelle3

	A	B	C	D	E	F	G
1	14	8	16	5	17	16	3
2
3
4
5	3
6	5
7	8
8	14
9	16
10	16
11	17
12
13

Formeln der Tabelle

A5 : =WENN(ZEILE(A1)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A1));"")
A6 : =WENN(ZEILE(A2)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A2));"")
A7 : =WENN(ZEILE(A3)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A3));"")
A8 : =WENN(ZEILE(A4)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A4));"")
A9 : =WENN(ZEILE(A5)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A5));"")
A10 : =WENN(ZEILE(A6)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A6));"")
A11 : =WENN(ZEILE(A7)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A7));"")
A12 : =WENN(ZEILE(A8)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A8));"")
A13 : =WENN(ZEILE(A9)<=ANZAHL($1:$1);KKLEINSTE($1:$1;ZEILE(A9));"")

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download

Gruß Sepp

AW: Zeile transponieren und sortieren

27.06.2006 22:19:42

Georg

Im Prinzip schon, aber bei mir scheint das noch nicht ganz zu funktionieren, Problem ist auch noch, dass es z.B. zwei erste Plätze geben kann (z.B. A1 = 1 und C1 = 1 usw...), vielleicht liegt dabei das Problem?

AW: Zeile transponieren und sortieren

27.06.2006 22:29:13

Josef

Hallo Georg!
Und wo ist dann das Problem?
Sollen Doppelte nicht doppelt ausgegeben werden?

Gruß Sepp

AW: Zeile transponieren und sortieren

27.06.2006 22:42:50

Georg

Ja, hi, ich mal wohl noch irgendwas falsch ;)
Ist dann wahrscheinlich ein Übertragungsfehler, meine Werte in der Zeile fangen bei c104 und gehen bis w104, die Werte ich ab der Spalte A, Zeile 108 auflisten. Vielleicht kannste mir ja nochmal dafür das erste Beispiel geben, dann krieg ich's ja vielleicht auf die Reihe!
Freundlische Grüße, Georg

AW: Zeile transponieren und sortieren

27.06.2006 22:48:13

Josef

Hallo Georg!

Tabelle3

	A	B	C	D	E	F	G	H	I	J
103
104			1	8	1	5	17	16	3
105
106
107
108	1	1
109	1	3
110	3	5
111	5	8
112	8	16
113	16	17
114	17
115
116

Formeln der Tabelle

A108 : =WENN(ANZAHL($C$104:$W$104)>=ZEILE(A1);KKLEINSTE($C$104:$W$104;ZEILE(A1));"")
B108 : =MIN($C$104:$W$104)
A109 : =WENN(ANZAHL($C$104:$W$104)>=ZEILE(A2);KKLEINSTE($C$104:$W$104;ZEILE(A2));"")
B109 : =WENN(MAX($C$104:$W$104)=MAX($B$108:B108);"";KGRÖSSTE($C$104:$W$104;ZÄHLENWENN($C$104:$W$104;">"&B108)))
A110 : =WENN(ANZAHL($C$104:$W$104)>=ZEILE(A3);KKLEINSTE($C$104:$W$104;ZEILE(A3));"")
B110 : =WENN(MAX($C$104:$W$104)=MAX($B$108:B109);"";KGRÖSSTE($C$104:$W$104;ZÄHLENWENN($C$104:$W$104;">"&B109)))
A111 : =WENN(ANZAHL($C$104:$W$104)>=ZEILE(A4);KKLEINSTE($C$104:$W$104;ZEILE(A4));"")
B111 : =WENN(MAX($C$104:$W$104)=MAX($B$108:B110);"";KGRÖSSTE($C$104:$W$104;ZÄHLENWENN($C$104:$W$104;">"&B110)))
A112 : =WENN(ANZAHL($C$104:$W$104)>=ZEILE(A5);KKLEINSTE($C$104:$W$104;ZEILE(A5));"")
B112 : =WENN(MAX($C$104:$W$104)=MAX($B$108:B111);"";KGRÖSSTE($C$104:$W$104;ZÄHLENWENN($C$104:$W$104;">"&B111)))
A113 : =WENN(ANZAHL($C$104:$W$104)>=ZEILE(A6);KKLEINSTE($C$104:$W$104;ZEILE(A6));"")
B113 : =WENN(MAX($C$104:$W$104)=MAX($B$108:B112);"";KGRÖSSTE($C$104:$W$104;ZÄHLENWENN($C$104:$W$104;">"&B112)))
A114 : =WENN(ANZAHL($C$104:$W$104)>=ZEILE(A7);KKLEINSTE($C$104:$W$104;ZEILE(A7));"")
B114 : =WENN(MAX($C$104:$W$104)=MAX($B$108:B113);"";KGRÖSSTE($C$104:$W$104;ZÄHLENWENN($C$104:$W$104;">"&B113)))
A115 : =WENN(ANZAHL($C$104:$W$104)>=ZEILE(A8);KKLEINSTE($C$104:$W$104;ZEILE(A8));"")

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download

Gruß Sepp

AW: Zeile transponieren und sortieren

27.06.2006 22:52:26

Georg

Suuuuper, herzlichen Dank :) mfG, Georg

Beliebteste Forumthreads (12 Monate)

Zeile transponieren und sortieren

Forumthread: Zeile transponieren und sortieren

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread