Nettoarbeitstage ohne vorgefertige Formel

Forumthread: Nettoarbeitstage ohne vorgefertige Formel

06.10.2006 12:36:58

Bernd

Hallo,
kann man eigentlich die Funktion der Berechnung von Nettoarbeitstagen auch irgendwie anders erreichen, wenn Nettoarbeitstage auf einem Rechner nicht verfügbar ist?
Gruss
Bernd

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Nettoarbeitstage ohne vorgefertige Formel

06.10.2006 12:56:13

AndrRo

Hallo Bernd,
Um die Nettoarbeitstagefunktion zu erhalten, muss du in EXTRAS/ADD-INS die 'Analyse-Funktionen' installieren. Dann steht diese Funktion auch zur Verfügung.
Gruss
Andreas

AW: Nettoarbeitstage ohne vorgefertige Formel

06.10.2006 13:02:08

Bernd

Danke, das weiß ich auch.
Es ging mir aber gerade darum es ohne diese Formel zu realisieren. Denn die Aktivierung gestaltet sich mit unter auf Rechnern mit eingesschränkten Rechten (netzwerk) etwas schwierig.
Gruss

AW: Nettoarbeitstage ohne vorgefertige Formel

06.10.2006 13:00:05

HermannZ

hallo Bernd;
meinst du das so?
Beispiel;

	A	B	C	D
2	Ausgangsdatum	Enddatum	Mit Funktion	Ohne Funktion
3			Nettoarbeitstage	Nettoarbeittage
4	02.03.2006	10.03.2006	7	7
5	01.10.2005	17.10.2005	11	11
6	10.10.2005	17.10.2005	6	6
7	31.10.2005	31.12.2005	45	45
8

Formeln der Tabelle

C4 : =NETTOARBEITSTAGE(A4;B4;Feier)
D4 : {=SUMME(N(WOCHENTAG(ZEILE(INDIREKT(A4&":"&B4));2)<6))-SUMME(($I$4:$I$24>=A4)*($I$4:$I$24<=B4)*(WOCHENTAG($I$4:$I$24;2)<6))}
C5 : =NETTOARBEITSTAGE(A5;B5;Feier)
D5 : {=SUMME(N(WOCHENTAG(ZEILE(INDIREKT(A5&":"&B5));2)<6))-SUMME(($I$4:$I$24>=A5)*($I$4:$I$24<=B5)*(WOCHENTAG($I$4:$I$24;2)<6))}
C6 : =NETTOARBEITSTAGE(A6;B6;Feier)
D6 : {=SUMME(N(WOCHENTAG(ZEILE(INDIREKT(A6&":"&B6));2)<6))-SUMME(($I$4:$I$24>=A6)*($I$4:$I$24<=B6)*(WOCHENTAG($I$4:$I$24;2)<6))}
C7 : =NETTOARBEITSTAGE(A7;B7;Feier)
D7 : {=SUMME(N(WOCHENTAG(ZEILE(INDIREKT(A7&":"&B7));2)<6))-SUMME(($I$4:$I$24>=A7)*($I$4:$I$24<=B7)*(WOCHENTAG($I$4:$I$24;2)<6))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
gruss Hermann

AW: Nettoarbeitstage ohne vorgefertige Formel

06.10.2006 13:03:18

Bernd

Perfekt, genau das meinte ich.

AW: Korrektur............mT.

06.10.2006 13:10:01

HermannZ

hallo bernd;
sorry hatte falsches beispiel kopiert es fehlte die Feiertagstabelle,die aber in der von mir angegebenen Formel enthalten ist.
neues Beispiel;

	A	B	C	D	E	F	G	H	I	J
2	Ausgangsdatum	Enddatum	Mit Funktion	Ohne Funktion	Nettoarbeittage	Nettoarbeittage		Feiertage in	2006
3			Nettoarbeitstage	Nettoarbeittage	bei 6 Tage Woche	bei 6 Tage Woche
4	02.03.2006	10.03.2006	7	7	7	8		Neujahr	01.01.2006
5	01.10.2005	17.10.2005	11	11	11	14		hl. 3 Könige	06.01.2006	x
6	10.10.2005	17.10.2005	6	6	6	7		Rosenmontag	27.02.2006	x
7	31.10.2005	31.12.2005	45	45	45	54		Karfreitag	14.04.2006
8								Ostersamstag	15.04.2006	x
9								Ostersonntag	16.04.2006
10								Ostermontag	17.04.2006
11								Maifeiertag	01.05.2006
12								Muttertag	14.05.2006	x
13								Christi Himmelfahrt	25.05.2006
14								Pfingstsamstag	03.06.2006	x
15								Pfingstsonntag	04.06.2006
16								Pfingstmontag	05.06.2006
17								Fronleichnam	15.06.2006	x
18								Nationalfeiertag	03.10.2006
19								Reformationstag	31.10.2006	x
20								Allerheiligen	01.11.2006	x
21								hl. Abend	24.12.2006	x
22								1. Weihnachtstag	25.12.2006
23								2. Weihnachtstag	26.12.2006
24								Silvester	31.12.2006	x
25
26										Wenn "x"
27										wird der
28										Feiertag
29										berücksichtigt

Formeln der Tabelle

C4 : =NETTOARBEITSTAGE(A4;B4;Feier)
D4 : {=SUMME(N(WOCHENTAG(ZEILE(INDIREKT(A4&":"&B4));2)<6))-SUMME(($I$4:$I$24>=A4)*($I$4:$I$24<=B4)*(WOCHENTAG($I$4:$I$24;2)<6))}
E4 : =SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A4&":"&B4));2)<6)*ISTNV(VERGLEICH(ZEILE(INDIREKT(A4&":"&B4));Feier;)))
F4 : =SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A4&":"&B4));2)<7)-SUMME(ISTZAHL(VERGLEICH(ZEILE(INDIREKT(A4&":"&B4));Feier;))))
I4 : =DATWERT("01.01."&I2)
C5 : =NETTOARBEITSTAGE(A5;B5;Feier)
D5 : {=SUMME(N(WOCHENTAG(ZEILE(INDIREKT(A5&":"&B5));2)<6))-SUMME(($I$4:$I$24>=A5)*($I$4:$I$24<=B5)*(WOCHENTAG($I$4:$I$24;2)<6))}
E5 : =SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A5&":"&B5));2)<6)*ISTNV(VERGLEICH(ZEILE(INDIREKT(A5&":"&B5));Feier;)))
F5 : =SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A5&":"&B5));2)<7)-SUMME(ISTZAHL(VERGLEICH(ZEILE(INDIREKT(A5&":"&B5));Feier;))))
I5 : =WENN(J5="x";DATWERT("06.01."&I2);0)
C6 : =NETTOARBEITSTAGE(A6;B6;Feier)
D6 : {=SUMME(N(WOCHENTAG(ZEILE(INDIREKT(A6&":"&B6));2)<6))-SUMME(($I$4:$I$24>=A6)*($I$4:$I$24<=B6)*(WOCHENTAG($I$4:$I$24;2)<6))}
E6 : =SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A6&":"&B6));2)<6)*ISTNV(VERGLEICH(ZEILE(INDIREKT(A6&":"&B6));Feier;)))
F6 : =SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A6&":"&B6));2)<7)-SUMME(ISTZAHL(VERGLEICH(ZEILE(INDIREKT(A6&":"&B6));Feier;))))
I6 : =WENN(J6="x";I9-48;0)
C7 : =NETTOARBEITSTAGE(A7;B7;Feier)
D7 : {=SUMME(N(WOCHENTAG(ZEILE(INDIREKT(A7&":"&B7));2)<6))-SUMME(($I$4:$I$24>=A7)*($I$4:$I$24<=B7)*(WOCHENTAG($I$4:$I$24;2)<6))}
E7 : =SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A7&":"&B7));2)<6)*ISTNV(VERGLEICH(ZEILE(INDIREKT(A7&":"&B7));Feier;)))
F7 : =SUMMENPRODUKT((WOCHENTAG(ZEILE(INDIREKT(A7&":"&B7));2)<7)-SUMME(ISTZAHL(VERGLEICH(ZEILE(INDIREKT(A7&":"&B7));Feier;))))
I7 : =I9-2
I8 : =WENN(J8="x";I9-1;0)
I9 : =RUNDEN((TAG(MINUTE(I2/38)/2+55)&".4."&I2)/7;)*7-6
I10 : =I9+1
I11 : =DATWERT("01.05."&I2)
I12 : =WENN(J12="x";WENN(WOCHENTAG(I11)=1;I11+7;I11-WOCHENTAG(I11)+15);0)
I13 : =I9+39
I14 : =WENN(J14="x";I9+48;0)
I15 : =I9+49
I16 : =I9+50
I17 : =WENN(J17="x";I9+60;0)
I18 : =DATWERT("03.10."&I2)
I19 : =WENN(J19="x";DATWERT("31.10."&I2);0)
I20 : =WENN(J20="x";DATWERT("01.11."&I2);0)
I21 : =WENN(J21="x";DATWERT("24.12."&I2);0)
I22 : =DATWERT("25.12."&I2)
I23 : =DATWERT("26.12."&I2)
I24 : =WENN(J24="x";DATWERT("31.12."&I2);0)
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
gruss hermann

AW: Korrektur............mT.

06.10.2006 13:38:12

Bernd

Oh, das mit der Feiertagstabelle (vor allem mit den Kreuzen) ist ja noch besser.
Danke dir :-))

AW: Danke für die Rückantwort.........oT.

06.10.2006 13:45:47

HJermannZ

AW: Korrektur............mT.

06.10.2006 13:46:08

Bernd

Nebenbei bemerkt: sind das wirklich alle Feiertage, die es gibt?
Und wieso führst du Feiertagen auf Sonntagen auch noch auf. Die werden doch ohnehin nicht berücksichtigt, oder?

AW: Korrektur............mT.

06.10.2006 14:12:20

HermannZ

Hallo bernd;
dieses ist nur ein Beispiel wie man so was machen kann ,die Liste kann ja auch wie man will erweitert werden.
das mit den Sonntagen ist so, da ja ein Feiertag sowohl in die Woche oder auf einen Samstag oder Sonntag fallen kann müsste mann ja wenn die Liste nicht Datumsabhängig wäre die Liste immer jedes jahr neu schreiben und so entfällt das da die Formel ja kontrolliert ob der angegebene Tag ein Samstag,Sonntag oder Feiertag ist und dann ausgeschlossen wird.
Gruss hermann

Beliebteste Forumthreads (12 Monate)

Nettoarbeitstage ohne vorgefertige Formel

Forumthread: Nettoarbeitstage ohne vorgefertige Formel

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread