Zelleninhalt umwandeln

Forumthread: Zelleninhalt umwandeln

23.10.2006 13:40:16

Jörn

Hallo zusammen, ich habe folgendes Problem. Ein Freund hat mir ein Excel Datei zugeschickt. In einer Spalte dieser Datei sind Zeiträume aufgelistet: 0 seconds; 8 days 4 hours 5 minutes 2 seconds; 12 hours 2 minutes usw .......
Ich benötige die Zeiträume jedoch im Format dd:hh:mm:ss. Besteht eine Möglichkeit diese Zeiträume in das Format umzuwandeln?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zelleninhalt umwandeln

23.10.2006 14:20:30

Jörn

Hallo, sorry, ich meinte das Format: hh:mm:ss

AW: Zelleninhalt umwandeln

23.10.2006 15:21:06

ingUR

Hallo, Jörn,
hilfreich wäre eine Beispiespieldatei, in der man erkennen könnte, in welcher Systematik die Datensätze in der Tabelle vorliegen.
Ich gehe davon aus, dass jeder durch Semikolon getrennte Datensstz, für sich in eienr Zeile steht.
Wenn der Eintrag z.B. in der Zelle A1 steht, dann kann entweder über die Teilzerlegung der Textkette in A1 gegangen werden oder aber der gesamte String in einer Formel neu gestaltet werden:

	A	B	C	D	E	F	G
1	8 days 4 hours 5 minutes 2 seconds	192	4	5	2		192:04:05:02

Formeln der Tabelle

B1 : =24*WENN(ISTZAHL(FINDEN("days";A1));WERT(LINKS(A1;FINDEN("days";A1)-1));0)
C1 : =WENN(ISTZAHL(FINDEN("hours";A1));WERT(WENN(ISTZAHL(FINDEN("days";A1));TEIL(A1;FINDEN("days";A1)+5;FINDEN("hours";A1)-FINDEN("days";A1)-5);LINKS(A1;FINDEN("hours";A1)-1)));0)
D1 : =WENN(ISTZAHL(FINDEN("minutes";A1));WERT(WENN(ISTZAHL(FINDEN("hours";A1));TEIL(A1;FINDEN("hours";A1)+6;FINDEN("minutes";A1)-FINDEN("hours";A1)-6);LINKS(A1;FINDEN("minutes";A1)-1)));0)
E1 : =WENN(ISTZAHL(FINDEN("seconds";A1));WERT(WENN(ISTZAHL(FINDEN("minutes";A1));TEIL(A1;FINDEN("minutes";A1)+8;FINDEN("seconds";A1)-FINDEN("minutes";A1)-8);LINKS(A1;FINDEN("seconds";A1)-1)));0)
G1 : =WENN(ISTZAHL(FINDEN("days";A1));24*WERT(LINKS(A1;FINDEN("days";A1)-1));0)&":"&TEXT(WENN(ISTZAHL(FINDEN("hours";A1));(WENN(ISTZAHL(FINDEN("days";A1));TEIL(A1;FINDEN("days";A1)+5;FINDEN("hours";A1)-FINDEN("days";A1)-5);LINKS(A1;FINDEN("hours";A1)-1)));0);"00")&":"&TEXT(WENN(ISTZAHL(FINDEN("minutes";A1));WERT(WENN(ISTZAHL(FINDEN("hours";A1));TEIL(A1;FINDEN("hours";A1)+6;FINDEN("minutes";A1)-FINDEN("hours";A1)-6);LINKS(A1;FINDEN("minutes";A1)-1)));0);"00")&":"&TEXT(WENN(ISTZAHL(FINDEN("seconds";A1));WERT(WENN(ISTZAHL(FINDEN("minutes";A1));TEIL(A1;FINDEN("minutes";A1)+8;FINDEN("seconds";A1)-FINDEN("minutes";A1)-8);LINKS(A1;FINDEN("seconds";A1)-1)));0);"00")

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Es handelt sich natürlich nit um ein gültiges Uhrzeitformat, da Stunden und kleinere Einheiten von dieser nur als Bruchteil eines Tages angegeben werden können ( hh:mm mit 12:00 entspericht 0,5 Tage).
Gruß,
Uwe

AW: Zelleninhalt umwandeln

23.10.2006 15:04:11

fcs

Hallo Jörn,
mit folgender leider sehr langen Formel kannst du den Text in die excelinterne Zeit in Tagen umrechnen.
Mit dem benutzerdefinierten Format TT\:hh:mm:ss kannst du den Inhalt dann in der gewünschten Form anzeigen
0 seconds 00:00:00:00 18 days 4 hours 5 minutes 2 seconds 18:04:05:02 2 hours 2 minutes 00:02:02:00 2 minutes 00:00:02:00 Formel in B1: =WENN(ISTFEHLER(SUCHEN("days";A1;1));0;WERT(LINKS(A1;SUCHEN(" days";A1;1)-1))) + WENN(ISTFEHLER(SUCHEN("hours";A1;1));0; WENN(ISTFEHLER(SUCHEN("days";A1;1)); WERT(LINKS(A1;SUCHEN(" hours";A1;1)-1));WERT(TEIL(A1;SUCHEN(" hours";A1;1)-2;2))))/24 + WENN(ISTFEHLER(SUCHEN("minutes";A1;1));0;WENN(ISTFEHLER(SUCHEN("hours";A1;1)); WERT(LINKS(A1;SUCHEN(" minutes";A1;1)-1));WERT(TEIL(A1;SUCHEN(" minutes";A1;1)-2;2))))/24/60 + WENN(ISTFEHLER(SUCHEN("seconds";A1;1));0;WENN(ISTFEHLER(SUCHEN("minutes";A1;1)); WERT(LINKS(A1;SUCHEN(" seconds";A1;1)-1));WERT(TEIL(A1;SUCHEN(" seconds";A1;1)-2;2))))/24/60/60

AW: Zelleninhalt umwandeln - Korektur Format

23.10.2006 15:07:27

fcs

Hallo Jörn,
als benutzerdefiniertes Format [hh]:mm:ss einstellen, dann werden Tage in Stunden umgerechnet
Gruß
Franz

AW: Zelleninhalt umwandeln - Korektur Format

23.10.2006 15:45:58

Jörn

Hallo Franz, vielen vielen Dank. Echt klasse. Klappt sehr gut, nur habe ich ein zusätzliches Problem. Und zwar gibt es auch Angaben wie "6 days 41 seconds". oder "6 days 1 minutes 54 seconds"

AW: Zelleninhalt umwandeln - Korektur Format

23.10.2006 16:16:42

fcs

Hallo Jörn,
ich hab die Formel noch ein wenig umgebaut, so dass jetzt auch in der Mitte fehlende Zeitangaben berechnet werden.
Mein eigentliches Problem bei der Berechnung sind 1-stellige Zahlen zu Beginn der Angabe gewesen, wenn die Tages- bzw. Stunden und Minutenangabe fehlten. Das ist jetzt bereinigt.
Gruß
Franz
=WENN(ISTFEHLER(SUCHEN("days";A1;1));0;WERT(LINKS(A1;SUCHEN(" days";A1;1)-1))) + WENN(ISTFEHLER(SUCHEN("hours";A1;1));0; WENN(ISTFEHLER(WERT(TEIL(A1;SUCHEN(" hours";A1;1)-2;2))); WERT(TEIL(A1;SUCHEN(" hours";A1;1)-1;1));WERT(TEIL(A1;SUCHEN(" hours";A1;1)-2;2))))/24 + WENN(ISTFEHLER(SUCHEN("minutes";A1;1));0;WENN(ISTFEHLER(WERT(TEIL(A1;SUCHEN(" minutes";A1;1)-2;2))); WERT(TEIL(A1;SUCHEN(" minutes";A1;1)-1;1));WERT(TEIL(A1;SUCHEN(" minutes";A1;1)-2;2))))/24/60 + WENN(ISTFEHLER(SUCHEN("seconds";A1;1));0;WENN(ISTFEHLER(WERT(TEIL(A1;SUCHEN(" seconds";A1;1)-2;2))); WERT(TEIL(A1;SUCHEN(" seconds";A1;1)-1;1));WERT(TEIL(A1;SUCHEN(" seconds";A1;1)-2;2))))/24/60/60

Beliebteste Forumthreads (12 Monate)

Forumthread: Zelleninhalt umwandeln

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Zelleninhalt umwandeln

Forumthread: Zelleninhalt umwandeln

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread