Feiertage mit VBA hervorheben

Nils · 2006-11-11T14:25:15+00:00

Habe nun erfolgreich mein Dienstplan mit Excel erstellt. http://www.clumsy-net.de/dienstplan.zip Auf dem Tabellenblatt "Daten" habe ich die gesetzlichen Feiertage berechnet! Was ich mir nun vorstelle ist folgendes: Mit VBA programmieren und alle Zellen aller Blätter mit den berechneten Feiertagen vergleichen, bei gefundener Übereinstimmung, den Text "Feiertag" in die Zelle UNTER das Datum schreiben. Siehe Beispiel: http://www.clumsy-net.de/beispiel.jpg Die Zelle mit dem gefundenem Datum und die Zelle darüber mit dem Wochentag soll dann hellgrau ausgefüllt werden. Ist das möglich? Kann mir da jemand helfen?

Hallo Nils,
das mit der Zelle E51 war ein kleienr Programmierfehler meinerseits. Ist nun bereinigt.
Blattschutz wird Makro jetzt auch verarbeitet. Ist das Blatt geschützt, dann deaktivert das Makro ihn vorübergehend und schaltet ihn nach der bearbeitung wieder ein.
Laufindex:
Der Laufindex 1 bis 12 muß bleiben, er wird benötigt, um aus dem Feiertagsdatum den zugehörigen Blattnamen zu bestimmen.
Ich hab eine zusätzliche Schleife für die Schichten eingebaut. Falls es auch noch eine Nachtschicht geben sollte, dann muss du im Makro in der 4. Zeile das Array erweitern um einen Eintrag für die 2 Zeichen, die vor der Monatszahl stehen.
Gruss
Franz


Sub Feiertagemarkieren()
Dim wksDaten As Worksheet, wksMonat As Worksheet, Feiertag As Variant, Zelle As Range
Dim Zeile As Long, Monat As Integer, Bereich As Range
Dim Schichten, i As Integer, Schutz As Boolean
Schichten = Array("A-", "Z-")
Set wksDaten = Worksheets("Daten")
Zeile = 14 '1. Zeile mit Feiertag in Spalte G Blatt Daten
'vorhandene (alte) Feiertagseinträge löschen
For Monat = 1 To 12
For i = 0 To UBound(Schichten)
Set wksMonat = Worksheets(Schichten(i) & Format(Monat, "00"))
If wksMonat.ProtectContents = True Then
wksMonat.Unprotect
Schutz = True
Else
Schutz = False
End If
Set Bereich = Application.Union(wksMonat.Range("C20:G32"), wksMonat.Range("C67:G79"))
For Each Zelle In Bereich
If Zelle.Value = "Feiertag" Then
Zelle.ClearContents
Zelle.VerticalAlignment = xlVAlignCenter
Zelle.Font.Size = 18
Zelle.Offset(-2, 0).Range("A1:A2").Interior.ColorIndex = xlNone 'keine Farbe
End If
Next
If Schutz = True Then wksMonat.Protect
Next i
Next
'Feiertage markieren
Do
Feiertag = wksDaten.Cells(Zeile, "G")
If Feiertag = 0 Then Exit Do
For i = 0 To UBound(Schichten)
Set wksMonat = Worksheets(Schichten(i) & Format(Month(Feiertag), "00"))
If wksMonat.ProtectContents = True Then
wksMonat.Unprotect
Schutz = True
Else
Schutz = False
End If
Set Bereich = Application.Union(wksMonat.Range("C19:G31"), wksMonat.Range("C66:G78"))
For Each Zelle In Bereich
If Zelle.Value = Feiertag Then
Zelle.Offset(1, 0).Value = "Feiertag"
Zelle.Offset(1, 0).Font.Size = 10
Zelle.Offset(1, 0).VerticalAlignment = xlVAlignTop
Zelle.Offset(-1, 0).Range("A1:A2").Interior.ColorIndex = 15 'Hellgrau
End If
Next
If Schutz = True Then wksMonat.Protect
Next i
Zeile = Zeile + 2
Loop
End Sub

Hallo Franz,
die Datenblätter Z-01 bis Z-12 sind zur eingabe der möglichen Arbeitstage und ihrer Dauer gedacht. Es erfolgt noch (in Zukunft von mir) eine weitere Lohnberechnung. Die Blätter A-01 bis A-12 sind ausschließlich zum Ausdrucken gedacht, an ihnen soll der Anwender später nix verändern können / dürfen.
Nun zum Problem:
Betrifft Arbeitsblätter Z-01 bis Z-12:
Macht der Anwender in einer Zelle D5:29 und H5:29 ein Kreuz "x" wird dies automatisch in den vorgefertigten Ausdruck (entweder Frühschicht oder Spätschicht) an entsprechender Stelle übernommen. D.h. die Zellen in den Arbeitsblättern A-01 bis A-12 müssten entsprechend verknüpft werden, damit das auch geschieht.logisch.
Das Problem ist jetzt aber, dass das Makro diese Verknüpfungen löscht, wenn es das Wort "Feiertag" in die entsprechenden Zellen schreibt. Was ja auch eigentlich völlig korrekt ist, weil die Verknüpfung auch gelöscht werden sollte. Berechnet man jetzt aber die Feiertagsdaten für ein anderes Jahr, und lässt die Feiertage erneut berechnen und markieren, dann werden ja wieder zuerst die vorhandenen alten Einträge gelöscht, um dann im nächsten Schritt die neuen Feiertage zu markieren. Bei den alten Feiertagen ist jetzt aber nun die Verknüpfung immer noch weg, obwohl sie keine Feiertage mehr sind.
Das Makro müsste also so verändert werden, dass diese Verknüpfung bei allen Arbeitstagen erhalten bleibt. Auch wenn ein jetziger Arbeitstag mal ein Feiertag war.
Das wäre ein Problem, das andere ist denke ich nicht besonders aufwendig:
Die Zellen mit den Feiertagen müssten auch in den Blättern Z-01 bis Z-12 mit der Farbe "15" (hellgrau) hinterlegt werden. Nur eine Zellenhinterlegung, weiter nix.
Hier ist das aktuelle Dokument:
https://www.herber.de/bbs/user/38148.xls
Ich danke dir sehr Franz,
liebe grüße
Nils

Forumthread: Feiertage mit VBA hervorheben

16
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial