Word-Datei aus Excel erstellen

mtremer · 2007-01-30T13:10:47+00:00

Liebe Excel-Freunde, ich habe nun schon eine Weile recherchiert, aber nicht das gefunden, was ich gerne machen würde. Ich will einen CommandButton programmieren, der bei Klick folgende Schritte durchläuft: - Word öffnen - neues Dokument erstellen - Adresse des Empfängers eintragen: Name A1, Strasse+Nr. A2, PLZ+Ort A3 der aktiven Exceldatei - Betreffzeile fett - 5 Zeilen Freitext - 2 Unterschriftsberechtigte: Name1 B1, Name2 B2 der aktiven Exceldatei Ist das möglich? Dank diesem Forum konnte ich bereits auf ähnlichem Weg mit Outlook eine Mail generieren. Ich hoffe, Ihr könnt mir bei meinem Problem helfen... Danke. Viele Grüße Marco

Hallo mtremer,
das Datum hab ich jetzt auch über Tabulatoren eingetragen. Mit dem Word Objektmodell kenn ich mich leider auch nicht wirklich aus. Ein rechtsbündiges Datum bekommst du nur über eine zweispaltige Tabelle. Probier doch einfach selbst mal ein bisschen mit Makro Aufzeichnen in Word herum.
Die anderen Geschichten hab ich dir in's Makro integriert. Hier nochmal das komplette Makro:

Sub Daten_nach_Word()
Dim wdApp As Object
Dim wdoc As Object
Dim ab As Byte
On Error Resume Next
Set wdApp = GetObject(, "Word.Application")
On Error GoTo 0
If wdApp Is Nothing Then
   Set wdApp = CreateObject("Word.Application")
   wdApp.Visible = True
End If
wdApp.Documents.Add
Set wdoc = wdApp.ActiveDocument
With wdApp.Selection
   .TypeText Text:=CStr(Range("A1"))
   For ab = 1 To 10
      .TypeText Text:=vbTab
   Next 'ab
   .TypeText Text:=Format(Date, "dd.mm.yyyy")
   .TypeParagraph
   .TypeText Text:=CStr(Range("A2"))
   .TypeParagraph
   .TypeText Text:=CStr(Range("A3"))
   For ab = 1 To 6
      .TypeParagraph
   Next 'ab
   .TypeText Text:="Betreff: "
   For ab = 1 To 9
      .TypeParagraph
   Next 'ab
   .TypeText Text:=CStr(Range("B1"))
   For ab = 1 To 5
      .TypeText Text:=vbTab
   Next 'ab
   .TypeText Text:=CStr(Range("B2"))
End With
wdoc.Paragraphs(9).Range.Font.Bold = True
With wdoc.Paragraphs(13).Range
   .ParagraphFormat.Alignment = 3
   .ParagraphFormat.LineSpacingRule = 1
   .Select
   wdApp.Selection.TypeText Text:="Bitte hier Text eintragen"
   .Select
End With
wdApp.Activate
Set wdoc = Nothing
Set wdApp = Nothing
End Sub
Gruß Ingolf

Hallo mtremer,
in der Codezeile meckert er nicht wegen "CentimetersToPoints", sondern wegen "wdAlignTabRight" und wegen "wdTabLeaderSpaces". Der gemeinsame Beginn mit "wd" deutet schon darauf hin. Bei diesen beiden Ausdrücken handelt es sich um Konstanten, die von Word zur Verfügung gestellt werden. Excel kennt diese Konstanten nicht und meckert daher beim Kompilieren des Makros.
Es gibt zwei Möglichkeiten, das abzustellen. Die starre Möglichkeit: Du kannst die Word Objektbibliothek fest in dein Excel einbinden. Dazu gehst du im Excel-VBA-Editor über das Menü Extras-Verweise und machst ein Häkchen bei "Microsoft Word 10.0 Object Library". Die Version muss bei dir nicht unbedingt 10.0 sein - 10.0 entspricht der Office2002-Version. Nachteil dieser Methode ist, dass das bei jedem Excel, d.h. bei jeder neuen Kombination aus User/PC gemacht werden muss, auf dem das Makro laufen soll. Die flexible Möglichkeit: Verzichte auf das Einbinden der Word-Objektbibliothek per Häkchen bei den Verweisen und verzichte auf alle Wordkonstanten. Jede Wordkonstante hat ihren Wert, der an Stelle der Konstanten verwendet werden kann. "wdAlignTabRight" hat den Wert 3, "wdTabLeaderSpaces" hat den Wert 0. Die Werte lassen sich für alle Wordkonstanten leicht herausfinden. Gehe dazu in den Word-VBA-Editor. Lass dir gegebenenfalls über Strg+G den Direktbereich anzeigen. Schreib nun in den Direktbereich ein Fragezeichen, gefolgt von einer Wordkonstanten (ohne Leerzeichen dazwischen!) und drücke auf Enter. Der Wert der Konstanten erscheint eine Zeile tiefer im Direktbereich.
Die weiteren Formatierungen für das gesamte Dokument kriegst du so hin (hier hab ich übrigens auch den Wert 3 an Stelle der Wordkonstanten "wdLineSpace1pt5" verwendet):

With ThisDocument.Range
   .Font.Name = "Univers"
   .Font.Size = 11.5
   .ParagraphFormat.LineSpacingRule = 3
End Sub
Gruß Ingolf

Forumthread: Word-Datei aus Excel erstellen

13
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial