Tabellen zusammenfügen

Forumthread: Tabellen zusammenfügen

10.02.2007 15:31:18

Mister

Hallo Excel-Profis,
ich weiß es gibt eine Menge Beiträge im Archiv darüber aber ich habe nichts passendes gefunden bzw. meine VBA Kenntnisse reichen nicht aus um die Beispiele meinen Bedürfnissen anzupassen.
Ich möchte lediglich die Inhalte der Spalten A:K der Tabellen "Tab1", "Tab2" und "Tab3" in ein vorhandenes Tabellenblatt ("Schnellsuche") kopieren. Beim Schliessen meiner Datei sollen die Einträge im Tabellenblatt ("Schnellsuche") komplett gelöscht werden.
Wer kann helfen? Ich bedanke mich für eure Unterstützung.
Gruß
Mister B

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Tabellen zusammenfügen

10.02.2007 17:08:57

fcs
AW: Tabellen zusammenfügen

10.02.2007 17:34:04

Mister

AW: Tabellen zusammenfügen

10.02.2007 17:08:57

fcs

Hallo Mister B,
nachfolgend die erforderlichen Makros
Gruss
Franz


im VBA-Editor unter "DieseArbeitsmappe" einfügen
Private Sub Workbook_BeforeClose(Cancel As Boolean)
'Daten im Blatt schnellsuche löschen
ThisWorkbook.Worksheets("Schnellsuche").UsedRange.Clear
ThisWorkbook.Save
End Sub
im VBA-Editor in ein Modul einfügen
Sub Tab1bis3nachSchnellsuche()
Dim wks As Worksheet, wksSchnell As Worksheet, Tabs As Variant
Dim ZeileSuche As Long, Zeile As Long, Zeile1 As Long
Dim Spalte1 As Integer, SpalteL As Integer, Spalte As Integer
Set wksSchnell = Worksheets("Schnellsuche")
ZeileSuche = 1 'Einfügezeile im Blatt Schnellsuche
Zeile1 = 1 '1. zu kopierende Zeile in den Quelltabellen
Spalte1 = 1 '1. zu kopierende Spalte (A)
SpalteL = 11 'letzte zu kopierende Spalte (K)
Tabs = Array("Tab1", "Tab2", "Tab3") 'Blätter mit den Quelldaten
Application.ScreenUpdating = False
For i = LBound(Tabs) To UBound(Tabs)
Set wks = Worksheets(Tabs(i))
With wks
'Letzte Zeile mit Daten in Tabelle ermitteln
Zeile = Zeile1
For Spalte = Spalte1 To SpalteL
Zeile = Application.WorksheetFunction.Max(Zeile, .Cells(.Rows.Count, Spalte).End(xlUp).Row)
Next Spalte
'Zellen nach Schnellsuche kopieren
.Range(.Cells(Zeile1, Spalte1), .Cells(Zeile, SpalteL)).Copy Destination:=wksSchnell.Cells(ZeileSuche, 1)
ZeileSuche = ZeileSuche + Zeile - Zeile1 + 1
End With
Next i
Application.CutCopyMode = False
Application.ScreenUpdating = True
wksSchnell.Activate
End Sub

AW: Tabellen zusammenfügen

10.02.2007 17:34:04

Mister

Hallo Franz,
danke für deine Antwort. Ich werde deine Lösung erst Morgen ausprobieren können.
Gruß
Mister B

Beliebteste Forumthreads (12 Monate)

Forumthread: Tabellen zusammenfügen

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread