Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
852to856
852to856
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Feiertage als Zellkommentar

Forumthread: Feiertage als Zellkommentar

Feiertage als Zellkommentar
17.03.2007 13:17:40
Harald
Hallo Excelgemeinde,
hatt einer von Euch einen Tip, wie ich Feiertage in einem Kallender als Zellkommentar darstellen kann ?
Im vorraus Vielen Dank für jeden Tip
MfG elmoro
Anzeige

7
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Feiertage als Zellkommentar
17.03.2007 13:30:05
Klaus-Dieter
Hallo Harald,
habe mich da mal mit beschäftigt. https://www.herber.de/bbs/user/41139.zip
Musst du mal sehen, ob dir das weiter hilft.
Viele Grüße Klaus-Dieter

Online-Excel
Anzeige
AW: Feiertage als Zellkommentar
17.03.2007 14:27:00
Harald
Hallo Klaus-Dieter,
vielen Dank für Deine schnelle Antwort.
Deine Datei ist VBA-Passwort geschützt, aber das war nicht mein Problem.
Dein Kallender ist Horizontal und meiner vertikal, dadurch ist es im VBA code doch etwas
anders aufgebaut wie ich es brauche und ich hab leider keine Ahnung wie ich das umstellen kann.
Auch ersehe ich im Code nicht, woher er die Daten für den Feiertag hernimmt.
Also wie gesagt, ich sehe keinen Stich wie es lang geht.;-(
MfG harald
Anzeige
AW: Feiertage als Zellkommentar
17.03.2007 15:44:00
Josef
Hallo Harald,
wo sind die Fereirtage hinterlegt?
Wie ist der kalender aufgebaut?
Vielleicht kannst du deinen Kalender hochladen.
Gruß Sepp
AW: Feiertage als Zellkommentar
17.03.2007 18:42:33
Harald
Hallo Sepp,
Leider ist der Kalender schon atwas zu gross geraten um ihn hochzuladen.
Bei meinem mikrigen analog Anschluss.
Aber ich kann Dir sagen in welchen Zellen die Datums daten
stehen: C10:C17,C22:C28,C33:C39,C44:C50,C55:C62
Die Zellen sind immer mit Zwischenräumen, weil dieser Kalender ein Teil einer
Arbeitszeiterfassung ist und dazwischen sind immer Zellen für die einzelnen
Wochenberechnungen.
Vieleicht kannst Du ja trotzdem was mit anfangen.
Ich hab schon hin und her probiert ich komme nicht weiter.
Vielen Dank Harald
Anzeige
AW: Feiertage als Zellkommentar
17.03.2007 19:28:00
Josef
Hallo Harald,
die in der Funktion "Feiertage" hinterlegten Feiertage musst du halt anpassen.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

'C10:C17,C22:C28,C33:C39,C44:C50,C55:C62


Sub addCelebrationComment()
Dim rng As Range, rngD As Range
Dim strTemp

Set rngD = Sheets("Kalender").Range("C10:C17,C22:C28,C33:C39,C44:C50,C55:C62") 'Tabellenname anpassen

rngD.ClearComments

For Each rng In rngD
    If IsDate(rng) And rng <> "" Then
        strTemp = Feiertage(rng.Value)
        If strTemp <> "" Then
            rng.AddComment strTemp
            rng.Comment.Shape.TextFrame.AutoSize = True
        End If
    End If
Next

End Sub
Public Function Feiertage(Datum As Date)
Dim J As Integer
Dim O As Date
J = Year(Datum)
O = Ostern(J)
Select Case Datum
    Case Is = DateSerial(J, 1, 1)
        Feiertage = "Neujahr"
    Case Is = DateSerial(J, 1, 6)
        Feiertage = "Dreikönig"
    Case Is = O
        Feiertage = "Ostersonntag"
    Case Is = DateAdd("D", 1, O)
        Feiertage = "Ostermontag"
    Case Is = DateSerial(J, 5, 1)
        Feiertage = "Erster Mai"
    Case Is = DateAdd("D", 39, O)
        Feiertage = "Christi Himmelfahrt"
    Case Is = DateAdd("D", 49, O)
        Feiertage = "Pfingstsonntag"
    Case Is = DateAdd("D", 50, O)
        Feiertage = "Pfingstmontag"
    Case Is = DateAdd("D", 60, O)
        Feiertage = "Fronleichnam"
    Case Is = DateSerial(J, 8, 15)
        Feiertage = "Maria Mimmelfahrt"
    Case Is = DateSerial(J, 10, 26)
        Feiertage = "NationalFeiertage"
    Case Is = DateSerial(J, 11, 1)
        Feiertage = "Allerheiligen"
    Case Is = DateSerial(J, 12, 8)
        Feiertage = "Maria Empfängnis"
    Case Is = DateSerial(J, 12, 24)
        Feiertage = "Heilig Abend"
    Case Is = DateSerial(J, 12, 25)
        Feiertage = "Christtag"
    Case Is = DateSerial(J, 12, 26)
        Feiertage = "Stefanitag"
    Case Is = DateSerial(J, 12, 31)
        Feiertage = "Silvester"
        '##Von Weihnachten abgeleitete Fest- und Gedenktage
    Case Is = DateSerial(J, 12, 25) - Weekday(DateSerial(J, 12, 25), 2) - 35
        Feiertage = "Volkstrauertag"
    Case Is = DateSerial(J, 12, 25) - Weekday(DateSerial(J, 12, 25), 2) - 32
        Feiertage = "Buss- u. Bettag"
    Case Is = DateSerial(J, 12, 25) - Weekday(DateSerial(J, 12, 25), 2) - 28
        Feiertage = "Totensonntag/Ewigkeitssonntag"
    Case Is = DateSerial(J, 12, 25) - Weekday(DateSerial(J, 12, 25), 2) - 21
        Feiertage = "1. Advent"
    Case Is = DateSerial(J, 12, 25) - Weekday(DateSerial(J, 12, 25), 2) - 14
        Feiertage = "2. Advent"
    Case Is = DateSerial(J, 12, 25) - Weekday(DateSerial(J, 12, 25), 2) - 7
        Feiertage = "3. Advent"
    Case Is = DateSerial(J, 12, 25) - Weekday(DateSerial(J, 12, 25), 2)
        Feiertage = "4. Advent"
        '##
    Case Else
        Feiertage = ""
End Select
End Function

Public Function Ostern(Year As Integer)
Dim D As Integer
D = (((255 - 11 * (Year Mod 19)) - 21) Mod 30) + 21
Ostern = DateSerial(Year, 3, 1) + D + (D > 48) + 6 - _
    ((Year + Year \ 4 + D + (D > 48) + 1) Mod 7)
End Function

Gruß Sepp
Anzeige
AW: Feiertage als Zellkommentar
18.03.2007 17:12:00
Harald
Hallo Sepp,
vielen Dank für Deinen Code, funzt einwandfrei.
Nochmal vielen Dank
Gruß Harald
AW: Feiertage als Zellkommentar
17.03.2007 18:48:50
Klaus-Dieter
Hallo Harald,
da das nur mit VBA geht, zumindest wenn es automatisch sein soll, bin ich davon ausgegangen, das du VBA-Kenntnisse hast. Habe inzwischen in deinem Level gesehen, das das wohl nicht so ist. Nun weiß ich aber nicht, wie ich dir helfen soll. Selber kannst du das nicht anpassen, ich weiß nicht wie dein Kalender aussieht. Also legen wir uns wieder hin.
Aber immerhin kannst du VBA-Passwörter umgehen. ;-) Tut mir leid, das da eins drin war. Da ich normalerweise damit nicht arbeite, habe ich nicht dran gedacht. Das war da nur zu Testzwecken drin. Hatte vergessen es wieder zu löschen. Für andere Interessenten es lautet * , kein Scherz es ist das Sternchen.
Viele Grüße Klaus-Dieter

Online-Excel
Anzeige
;

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige