Zellwerte in fremder Tabelle abbilden

Forumthread: Zellwerte in fremder Tabelle abbilden

23.03.2007 16:34:00

Mark

Guten Tag zusammen!
Ich hab ein etwas kniffliges Problem (zumindest für mich).
Ich habe eine Excel-Datei, die aus 2 Tabellenblättern besteht. Das 2. Tabellenblatt kann per Makro nach belieben dupliziert werden, auf ihm können in eine vorgefertigte Tabelle Name und Adresse, sowie Telefonnummern eingetragen werden, zusätzlich gibt es ein Feld für einen Freitext. Man kann sich das wie eine Oztlook - Visitenkarte vorstellen.
Nun soll auf dem 1. Tabellenblatt eine Liste entstehen, in der Name, Vorname und Telefonnummer aller Karteikarten eingetragen sind und das ganze dann automatisch. Eine Sortierung ist nicht zwingend notwendig. Ich möchte nur, dass wenn ich das 2. Tabellenblatt dupliziere, die Werte die ich dann dort in
bestimmte Zellen eintrage, auf dem 1. Tabellenblatt aufgelistet werden.
Ich hoffe, das war jetzt nicht zu kompliziert!
Kann mir jemand helfen?

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zellwerte in fremder Tabelle abbilden

24.03.2007 10:44:23

fcs

Hallo Mark,
es ist relativ aufwendig die Übersichtsliste zu aktualiseren in Anhängigkeit von Ereignissen/Aktivitäten in den Tabellen mit den Daten. Es müssen dann mehrere Sachen überprüft werden, damit die Daten immer in den korrekten Zeilen eingetragen werden.
Einfacher ist es die gesamte Liste immer dann zu aktualiiseren, wenn das Blatt mit der Liste ausgewählt wird.
Den Code fügst du im VBA-Editor unter der Tabelle ein, in der die Liste erstellt werden soll.
Im Code muss du die Zeilen zum Auslesen der Zellen anpassen/ergänzen und ggf. den Wert für die Startzeile (z.Zt. = 3) anpassen.
Gruß
Franz

Private Sub Worksheet_Activate()
'Code wird beim Anwählen des Tabellenblatts ausgeführt
Call BlattdatenAktualisieren(Me.Name, 3) ' 3 = Startzeile für Eintragen der Daten
End Sub
Sub BlattdatenAktualisieren(Blattname As String, Zeile1 As Integer)
'Daten aus den anderen Tabellenblättern werden als Liste im Blatt eingetragen
Dim wksQuelle As Worksheet, wksZiel As Worksheet
Dim Zeile As Long, Spalte As Integer
Set wksZiel = ThisWorkbook.Worksheets(Blattname)
Application.ScreenUpdating = False
With wksZiel
'Alte Daten in der Liste löschen
If .Cells.SpecialCells(xlCellTypeLastCell).Row >= Zeile1 Then
.Range(.Cells(Zeile1, 1), .Cells.SpecialCells(xlCellTypeLastCell)).ClearContents
End If
'Tabellenblätter auslesen
Zeile = Zeile1
For Each wksQuelle In ThisWorkbook.Worksheets
If wksQuelle.Name  wksZiel.Name Then
'Werte aus den  Zellen übertragen (Diese Zeilen entsprechend anpassen)
.Cells(Zeile, 1).Value = wksQuelle.Range("B3").Value 'Name
.Cells(Zeile, 2).Value = wksQuelle.Range("A3").Value 'Vorname
.Cells(Zeile, 3).Value = wksQuelle.Range("C3").Value 'Strasse
.Cells(Zeile, 4).Value = wksQuelle.Range("C4").Value 'PLZ
.Cells(Zeile, 5).Value = wksQuelle.Range("C5").Value 'Ort
.Cells(Zeile, 6).Value = wksQuelle.Range("B5").Value 'Telefonnummer
Zeile = Zeile + 1
End If
Next wksQuelle
'Datensortieren nach Spalte 1 und 2
.Range(.Cells(Zeile1, 1), .Cells.SpecialCells(xlCellTypeLastCell)).Sort _
Key1:=.Cells(Zeile1, 1), Order1:=xlAscending, Key2:=.Cells(Zeile1, 2), _
Order2:=xlAscending, Header:=xlNo
End With
Application.ScreenUpdating = True
End Sub

AW: Zellwerte in fremder Tabelle abbilden

24.03.2007 12:35:10

Mark

Hallo Franz,
vielen Dank für Deine schnelle und ausführliche Hilfe, sobald ich am Montag an meinen Arbeits PC komme, werde ich Deine Zeilen sofort in VBA übertragen, dann sag ich Dir auch sofort bescheid, ob es funktioniert hat, oder ich schreie nochmal ganz laut nach Hilfe!
In diesem Sinne noch ein schönes Wochenende!

AW: Zellwerte in fremder Tabelle abbilden

26.03.2007 20:00:00

Mark

Hall Franz!
Ich habe heute morgen Deinen Vorschlag in VBA einprogrammiert, also eigentlich ja nur Copy - Paste,
aber es funktioniert wunderbar!
In diesem Sinne nochmal Vielen Dank für die schnelle Hilfe!
MfG
Mark

Beliebteste Forumthreads (12 Monate)

Zellwerte in fremder Tabelle abbilden

Forumthread: Zellwerte in fremder Tabelle abbilden

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Zellwerte in fremder Tabelle abbilden

Forumthread: Zellwerte in fremder Tabelle abbilden

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread