jede dritte Zelle addieren

Forumthread: jede dritte Zelle addieren

20.06.2007 19:39:26

Andi

Guten Abend,
wer kann mir Helfen?
Beginnend in der Spalte B muss ich einer Zeile jede dritte Zelle addieren. ( Bis ca. Spalte ER)
Die Formel muss dann runter kopiert werden. ( Bis ca. Zeile 400)
Geht das überhaupt, ohne eine Formel einzugeben und alle Zellen einzeln anzugeben.
Dasselbe muss ich auch mit Min und Max machen...!
Vielen Dank für Eure Hilfe
Andi

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: jede dritte Zelle addieren

20.06.2007 19:44:00

jockel
jede dritte Zelle addieren mit erster zelle...

20.06.2007 19:55:26

jockel
AW: jede dritte Zelle addieren

20.06.2007 19:57:00

Andi
AW: jede dritte Zelle addieren

20.06.2007 20:42:25

jockel
AW: jede dritte Zelle addieren

20.06.2007 20:55:00

Andi
AW: jede dritte Zelle addieren

20.06.2007 21:26:49

Josef
Toll!!

20.06.2007 21:56:00

Andi

AW: jede dritte Zelle addieren

20.06.2007 19:44:00

jockel

hi Andi, schau mal hier: http://www.excelformeln.de/formeln.html?welcher=86

Tabelle1

	A	B	C	D
1	767
2	287
3	242
4	120
5	622
6	296
7	448
8	191
9	247
10	385
11	474
12	778
13	998
14	934
15	135
16	761
17	485
18	875
19	Summe	9045
20	Summe jede dritte zeile:	2573	2573	2573

Formeln der Tabelle

B19 : =SUMME(A1:A18)
B20 : {=SUMME((REST(ZEILE(A1:A18); 3)=0)*A1:A18)}
C20 : {=SUMME(WENN(REST(ZEILE(A1:A18); 3)=0;A1:A18))}
D20 : =SUMMENPRODUKT((REST(ZEILE(A1:A18); 3)=0)*A1:A18)
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
cu jörg
ein feedback wär ganz reizend

jede dritte Zelle addieren mit erster zelle...

20.06.2007 19:55:26

jockel

hi Andi:

Tabelle1

	A	B	C	D
1	767
2	287
3	242
4	120
5	622
6	296
7	448
8	191
9	247
10	385
11	474
12	778
13	998
14	934
15	135
16	761
17	485
18	875
19	Summe	9045
20	Summe jede dritte zeile:	3340	3340	3340

Formeln der Tabelle

B19 : =SUMME(A1:A18)
B20 : {=SUMME((REST(ZEILE(A1:A18); 3)=0)*A1:A18)+A1}
C20 : {=SUMME(WENN(REST(ZEILE(A1:A18); 3)=0;A1:A18))+A1}
D20 : =SUMMENPRODUKT((REST(ZEILE(A1:A18); 3)=0)*A1:A18)+A1
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
cu jörg
ein feedback wär ganz reizend

AW: jede dritte Zelle addieren

20.06.2007 19:57:00

Andi

Hallo Jockel,
ich habe die Zeile durch Spalte ersetzt, klappt aber nicht!
Nimmt die erste Zelle (B4) nicht mit...!
Gruß
Andi

AW: jede dritte Zelle addieren

20.06.2007 20:42:25

jockel

hi Andi, meinst du so?

Tabelle2

	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S	T
3		1	2	3	4	5	6	7	8	9	10	11	12	13	14	15	16	17	18
4		767	287	242	120	622	296	448	191	247	385	474	778	998	934	135	761	485	875	3340
5																				3340

Formeln der Tabelle

B3 : =SPALTE(A1)
C3 : =SPALTE(B1)
D3 : =SPALTE(C1)
E3 : =SPALTE(D1)
F3 : =SPALTE(E1)
G3 : =SPALTE(F1)
H3 : =SPALTE(G1)
I3 : =SPALTE(H1)
J3 : =SPALTE(I1)
K3 : =SPALTE(J1)
L3 : =SPALTE(K1)
M3 : =SPALTE(L1)
N3 : =SPALTE(M1)
O3 : =SPALTE(N1)
P3 : =SPALTE(O1)
Q3 : =SPALTE(P1)
R3 : =SPALTE(Q1)
S3 : =SPALTE(R1)
T4 : =SUMME(B4;D4;G4;J4;M4;P4;S4)
T5 : {=SUMME((REST(SPALTE(B4:S4)-1;3)=0)*B4:S4)+B4}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
cu jörg
ein feedbac wär ganz reizend

AW: jede dritte Zelle addieren

20.06.2007 20:55:00

Andi

Hallo Jörg
das klappt gut!
Nur Max und Min machen mir noch Sorgen! Vielen Dank auch.
Gruß
Andi

AW: jede dritte Zelle addieren

20.06.2007 21:26:49

Josef

Hallo Andi,
meinst du so?
Tabelle1

	DT	DU	DV	DW	DX	DY	DZ	EA	EB	EC	ED	EE	EF	EG	EH	EI	EJ	EK	EL	EM	EN	EO	EP	EQ	ER	ES	ET	EU	EV	EW
1																											Summe	Min	Max
2	354	228	270	419	121	572	331	420	205	425	404	565	544	250	429	354	396	389	294	289	586	323	577	136	264		16040	102	579
3	138	183	129	263	129	541	521	221	548	321	386	314	337	383	151	301	471	443	407	416	222	318	161	121	392		15098	104	594
4	275	213	215	126	180	203	558	121	152	598	464	499	120	558	398	236	399	189	333	378	435	290	502	291	558		17152	108	587

Formeln der Tabelle

Zelle	Formel
ET2	{=SUMME(WENN(REST(SPALTE($B2:$ER2)-1;3)=1;$B2:$ER2))}
EU2	{=MIN(WENN(REST(SPALTE($B2:$ER2)-1;3)=1;$B2:$ER2))}
EV2	{=MAX(WENN(REST(SPALTE($B2:$ER2)-1;3)=1;$B2:$ER2))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen Excel Jeanie HTML

Gruß Sepp

Toll!!

20.06.2007 21:56:00

Andi

Hallo Sepp,
kommentarlos vielen Dank auch! Einfach wunderbar!
Gruß
Andi

Infobox / Tutorial

Schritt-für-Schritt-Anleitung

Um jede dritte Zelle in Excel zu addieren, kannst du eine Matrixformel verwenden. Hier ist eine einfache Schritt-für-Schritt-Anleitung:

Zelle auswählen: Wähle die Zelle aus, in der die Summe angezeigt werden soll (z.B. B20).
Formel eingeben: Gib die folgende Formel ein:
```
{=SUMME(WENN(REST(ZEILE($B$2:$B$400)-1;3)=0;$B$2:$B$400))}
```
Diese Formel summiert alle Zellen in der Spalte B, die in jeder dritten Zeile Daten enthalten.
Formel bestätigen: Drücke STRG + SHIFT + ENTER, um die Matrixformel zu aktivieren. Die geschweiften Klammern {} werden automatisch hinzugefügt.
Formel kopieren: Du kannst die Formel nach rechts kopieren, um die Summe für andere Spalten zu berechnen.

Häufige Fehler und Lösungen

Fehler: Falsche Zellen werden summiert
Lösung: Stelle sicher, dass du den Bereich in der Formel korrekt angegeben hast. Überprüfe auch, ob du die Formel als Matrixformel eingegeben hast.
Fehler: Die erste Zelle wird nicht mit einbezogen
Lösung: Wenn du die Formel für Spalten anpassen möchtest, z.B. jede dritte Spalte addieren, ändere den Bereich entsprechend. Zum Beispiel:
```
{=SUMME(WENN(REST(SPALTE($B$2:$ER$2)-2;3)=0;$B$2:$ER$2))}
```

Alternative Methoden

SUMMENPRODUKT-Funktion: Eine alternative Methode zur Berechnung der Summe jeder dritten Zelle ist die Verwendung der SUMMENPRODUKT-Funktion:
```
=SUMMENPRODUKT((REST(ZEILE($B$2:$B$400)-1;3)=0)*$B$2:$B$400)
```
Pivot-Tabellen: Wenn du größere Datenmengen analysieren möchtest, kannst du auch Pivot-Tabellen verwenden, um jede zweite Zeile oder Spalte zu summieren.

Praktische Beispiele

Beispiel 1: Um die Summe jeder zweiten Zelle in einer Zeile zu berechnen, kannst du folgende Formel verwenden:
```
{=SUMME(WENN(REST(SPALTE($B$2:$ER$2)-1;2)=0;$B$2:$ER$2))}
```
Beispiel 2: Um den maximalen Wert jeder dritten Zelle zu finden, verwende:
```
{=MAX(WENN(REST(ZEILE($B$2:$B$400)-1;3)=0;$B$2:$B$400))}
```

Tipps für Profis

Einsetzen von Bedingungen: Du kannst die Formeln erweitern, um nur Werte zu summieren, die bestimmten Bedingungen entsprechen (z.B. nur positive Werte).
Verwendung von Namen: Benutze benannte Bereiche, um die Formeln übersichtlicher zu gestalten. Anstatt $B$2:$B$400 zu verwenden, kannst du einen Namen wie Datenbereich definieren.

FAQ: Häufige Fragen

1. Kann ich auch jede zweite Zelle in Excel addieren?
Ja, du kannst die Formel entsprechend anpassen. Zum Beispiel:

{=SUMME(WENN(REST(ZEILE($B$2:$B$400)-1;2)=0;$B$2:$B$400))}

2. Wie kann ich die Summe jeder zweiten Spalte berechnen?
Ändere die Formel wie folgt:

{=SUMME(WENN(REST(SPALTE($B$2:$ER$2)-1;2)=0;$B$2:$ER$2))}

3. Welche Excel-Version benötige ich für diese Funktionen?
Diese Funktionen sind in Excel 2010 und neueren Versionen verfügbar.

Beliebteste Forumthreads (12 Monate)

Forumthread: jede dritte Zelle addieren

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Jede dritte Zelle in Excel addieren

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread