Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
916to920
916to920
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Userform beim öffnen immer am 1. des Monats

Forumthread: Userform beim öffnen immer am 1. des Monats

Userform beim öffnen immer am 1. des Monats
17.10.2007 14:58:34
Patrick
Hallo,
vielleicht könnt ihr mir bei meinem folgenden Problem helfen:
Ich möchte es nach Möglichkeit realisieren, wenn ich am 1. des Monats (jedes Monat) meine Arbeitsmappe öffne, eine Userform (Datum) angezeigt wird. Die Userform dürfte aber nur am 1. angezeigt werden.
Gruß
Patrick

Anzeige

7
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Userform beim öffnen immer am 1. des Monats
17.10.2007 15:02:23
Josef
Hallo Patrick,
und was passiert, wenn der 1. ein Tag ist an dem die datei nicht geöffnet wird?
Gruß Sepp

AW: Userform beim öffnen immer am 1. des Monats
17.10.2007 15:03:00
Patrick
Hallo Sepp,
die Datei wird definitiv immer am 1. geöffnet.
Gruß
Patrick

Anzeige
AW: Userform beim öffnen immer am 1. des Monats
17.10.2007 15:06:08
Original
Hi,

Private Sub Workbook_Open()
If Day(Date) = 1 Then userform1.Show
End Sub


mfg Kurt

AW: Userform beim öffnen immer am 1. des Monats
17.10.2007 15:13:00
Patrick
Tausend dank Kurt - das war genau das was ich gebraucht habe. Um auf die Frage von Seppe nochmal zurückzukommen. Ich hab mir jetzt überlegt ob es nicht möglich ist wenn die Datei tatsächlich mal nicht am 1. geöffnet wird sonder z. Bsp. erst am 3. ob es nicht möglich das die Userform dann auch angezeigt wird. Sie sollte am nur 1x angezeigt werden ab dem 1. bis sie geöffnet wird.
Sorry habe die Frage von Sepp vorhin nicht so richtig verstanden.
Gruß
Patrick

Anzeige
AW: Userform beim öffnen immer am 1. des Monats
17.10.2007 15:21:35
Josef
Hallo Patrick,
siehst du ;-))
Ich würde es so lösen.
' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_Open()
If GetCustProp("Prüfdatum", CDate("01/01/1900")) <> CDate(DateSerial(Year(Date), Month(Date), 1)) Then
    SetCustProp "Prüfdatum", CDate(DateSerial(Year(Date), Month(Date), 1))
    UserForm1.Show
End If
End Sub

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Public Function GetCustProp(propName As String, Optional propValue As Variant) As Variant
' Wert aus Dateieigenschaft auslesen. Wenn nicht vorhanden
' Anlegen und Optional mit Startwert belegen

Dim propType As MsoDocProperties

If Not IsMissing(propValue) Then
    Select Case VarType(propValue)
        Case vbString
            propType = msoPropertyTypeString
        Case vbBoolean
            propType = msoPropertyTypeBoolean
        Case vbByte, vbInteger, vbLong
            propType = msoPropertyTypeNumber
        Case vbSingle, vbDouble
            propType = msoPropertyTypeFloat
        Case vbDate
            propType = msoPropertyTypeDate
        Case Else
    End Select
End If

With ThisWorkbook
    On Error GoTo NoName
    GetCustProp = .CustomDocumentProperties(propName).Value
    Exit Function
    NoName:
    If Err.Number = 5 Then
        Err.Clear
        .CustomDocumentProperties.Add _
            Name:=propName, _
            LinkToContent:=False, _
            Type:=propType, _
            Value:=propValue
        GetCustProp = propValue
    End If
End With
End Function

Public Function SetCustProp(propName As String, propValue As Variant)
' Wert in Dateieigenschaft schreiben. Wenn nicht vorhanden
' Anlegen und Wert eintragen

Dim propType As MsoDocProperties

Select Case VarType(propValue)
    Case vbString
        propType = msoPropertyTypeString
    Case vbBoolean
        propType = msoPropertyTypeBoolean
    Case vbByte, vbInteger, vbLong
        propType = msoPropertyTypeNumber
    Case vbSingle, vbDouble
        propType = msoPropertyTypeFloat
    Case vbDate
        propType = msoPropertyTypeDate
    Case Else
End Select

With ThisWorkbook
    On Error GoTo NoName
    .CustomDocumentProperties(propName).Value = propValue
    Exit Function
    NoName:
    If Err.Number = 5 Then
        Err.Clear
        .CustomDocumentProperties.Add _
            Name:=propName, _
            LinkToContent:=False, _
            Type:=propType, _
            Value:=propValue
    End If
End With
End Function

' **********************************************************************
' Modul: UserForm1 Typ: Userform
' **********************************************************************


Option Explicit

Gruß Sepp

Anzeige
AW: Userform beim öffnen immer am 1. des Monats
17.10.2007 16:12:14
Patrick
Super tausend Dank Sepp

Dann siehe Antwort von Kurt o.T.
17.10.2007 15:09:00
Kurt
Gruß Sepp

;

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige