Hilfetexte für Formular-Schaltflächen auf TB

reiner · 2008-08-03T20:37:00+00:00

Hallo Leute, den Befehlselementen auf einem UF können Hilfetexte (Control Tip Text) zur Erläuterung zugefügt werden, die den jeweiligen Text anzeigen wenn sich der Mauscorsor dem Befehlselement nähert. Weiß jemand ob solche Hilfetexte den Formular-Schaltflächen auf einem Tabellenblatt hinzugefügt werden können? Die Hilfetexte sollen -falls so etwas überhaupt möglich ist- angezeigt werden wenn sich der Mauscursor im unmittelbaren Bereich der Schaltfläche in ein Hand-Symbol verändert. mfg reiner

Hallo
Hier mal ein Workaraound mit Bordmitteln

Option Explicit
Public TempTextName As String
Public txtFrame As Boolean

Private Sub CommandButton1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    '(C) Ramses
    'Eigenes Tooltip für einen Commandbutton definieren
    Dim topCorner As Double, leftCornerTxt As Double, bottomCornerTxt As Double
    Dim oldCell As Range
    With Me.CommandButton1

        If Y > 3 And Y < .Height - 3 And X > 3 And X < .Width - 3 Then
        If txtFrame = True Then Exit Sub
            Set oldCell = ActiveCell
            leftCornerTxt = ActiveSheet.CommandButton1.Left + ActiveSheet.CommandButton1.Width
            bottomCornerTxt = ActiveSheet.CommandButton1.Top + ActiveSheet.CommandButton1.Height
            ActiveSheet.Shapes.AddLabel(msoTextOrientationHorizontal, leftCornerTxt, bottomCornerTxt, 0#, 0#).Select
            Selection.ShapeRange(1).TextFrame.AutoSize = msoTrue
            Selection.Characters.Text = "Dein Texthinweis:" & Chr$(10) & "(C) Ramses" & Chr$(10) & "Dein Text zur Anzeige"
            With Selection.Font
                .Name = "Arial"
                .FontStyle = "Standard"
                .Size = 10
            End With
            Selection.ShapeRange.Fill.ForeColor.SchemeColor = 43
            Selection.ShapeRange.Fill.Visible = msoTrue
            Selection.ShapeRange.Fill.Solid
            Selection.ShapeRange.Line.Weight = 1#
            Selection.ShapeRange.Line.Visible = msoTrue
            Selection.ShapeRange.Line.Style = msoLineSingle
            Selection.ShapeRange.Line.ForeColor.SchemeColor = 64
            TempTextName = Selection.Name
            txtFrame = True
            oldCell.Select
        Else
            On Error Resume Next
            With ActiveSheet.Shapes(TempTextName)
                .Delete
            End With
            txtFrame = False
        End If
    End With
End Sub

Den Code in deinen Commandbutton in der Zelle einfügen
Gruss Rainer

Hallo Kurt
Also schön,... extra für Dich :-)

Option Explicit

Public TempTextName As String
Public txtFrame As Boolean

Private Sub CommandButton1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    '(C) Ramses
    'Extra für Kurt ohne Select :-)
    'Eigenes Tooltip für einen Commandbutton definieren
    Dim topCorner As Double, leftCornerTxt As Double, bottomCornerTxt As Double
    Dim oldCell As Range
    Dim myTb As Shape
    With Me.CommandButton1
        'Infotip erst einblenden, bzw. wieder ausblenden, wenn Mauscourser
        'einen Bereich von 3 Points von den äusseren Rändern des Commandnuttons
        'überschreitet
        If Y > 3 And Y < .Height - 3 And X > 3 And X < .Width - 3 Then
        If txtFrame = True Then Exit Sub
            leftCornerTxt = ActiveSheet.CommandButton1.Left + ActiveSheet.CommandButton1.Width
            bottomCornerTxt = ActiveSheet.CommandButton1.Top + ActiveSheet.CommandButton1.Height
            Set myTb = ActiveSheet.Shapes.AddLabel(msoTextOrientationHorizontal, leftCornerTxt, bottomCornerTxt, 0#, 0#)
            With myTb
                .TextFrame.AutoSize = msoTrue
                With .OLEFormat.Object
                    .Text = "Dein Texthinweis:" & Chr$(10) & "(C) Ramses" & Chr$(10) & "Dein Text zur Anzeige"
                    .Font.Name = "Arial"
                    .Font.FontStyle = "Standard"
                    .Font.Size = 10
                    .ShapeRange.Fill.ForeColor.SchemeColor = 43
                    .ShapeRange.Fill.Visible = msoTrue
                    .ShapeRange.Fill.Solid
                    .ShapeRange.Line.Weight = 1#
                    .ShapeRange.Line.Visible = msoTrue
                    .ShapeRange.Line.Style = msoLineSingle
                    .ShapeRange.Line.ForeColor.SchemeColor = 64
                End With
                TempTextName = .Name
            End With
            txtFrame = True
        Else
            On Error Resume Next
            With ActiveSheet.Shapes(TempTextName)
                .Delete
            End With
            txtFrame = False
        End If
    End With
    Set myTb = Nothing
End Sub

Gruss Rainer

Hilfetexte für Formular-Schaltflächen auf TB

Forumthread: Hilfetexte für Formular-Schaltflächen auf TB

24
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Hilfetexte für Formular-Schaltflächen auf TB

Forumthread: Hilfetexte für Formular-Schaltflächen auf TB

24 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

24
Beiträge zum Forumthread

Beiträge zu diesem Forumthread