Emailadresse zusammensetzen aus Auflistung

Forumthread: Emailadresse zusammensetzen aus Auflistung

Karin

Guten Abend!
Ich brüte schon seit Stunden über folgendem Problem:
An eine Liste von Standard Emailadressen (Aufbau: Markt.xx@firma.de" soll eine Email mit jeweils einer speziellen entsprechenden Datei im Anhang ("10xx.pdf") gesandt werden.
Kann ich per For Each ... Next die Marktnummern als Emailempfänger definieren ( Nummern leider nicht fortlaufend) und dafür auch die jeweilige Datei anhängen (Marktnummer im Dateinamen enthalten)?
Im Moment habe ich eine Laien-Version, in der ich für jeden Markt untereinander die Emailadresse und die Anhangsdatei ausformuliert habe.
Weiß nicht, ob ich mich konkret genug ausgedrückt habe...
Bin dankbar für jede Hilfe!
Viele Grüße
Karin

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread

Betreff

Benutzer

AW: Emailadresse zusammensetzen aus Auflistung

Josef

AW: Emailadresse zusammensetzen aus Auflistung

06.04.2011 22:07:11

Josef

Hallo Karin,
ich habe angenommen, das die Marktnummern in Spalte A ab Zeile 2 stehen und das Outlook als Mailprogramm verwendet wird.
Ungetestet!

' **********************************************************************
' Modul: Modul1  Typ: Allgemeines Modul
' **********************************************************************
Option Explicit
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Sub MailToMarket()
  Dim rng As Range
  Dim strAddress As String, strFile As String, strPath As String
  Dim strA1 As String, strA2 As String
  strA1 = "markt." 'Adressteil VOR der Marktnummer - Anpassen!
  strA2 = "@firma.de" 'Adressteil NACH der Marktnummer - Anpassen!
  strPath = "C:\VerzeichnisDerPDF-Dateien" 'PDF-Pfad - Anpassen!
  strPath = IIf(Right(strPath, 1) = "\", strPath, strPath & "\")
  With Sheets("Markt")  'Tabellenname anpassen!
    For Each rng In .Range("A2:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
      If rng <> "" Then
        strAddress = strA1 & rng.Text & strA2
        strFile = strPath & "10" & rng.Text & ".pdf"
        SendMail strAddress, strFile
        Sleep 1000
      End If
    Next
  End With
End Sub

Sub SendMail(ByVal strTo As String, strAttachment As String)
  Dim objOL As Object
  Dim objMail As Object
  Set objOL = CreateObject("Outlook.Application")
  Set objMail = objOL.CreateItem(0)
  On Error Resume Next
  With objMail
    .To = strTo
    .CC = ""
    .BCC = ""
    .Subject = "Betreff"
    .Body = "Hallo!"
    If Dir(strAttachment, vbNormal) <> "" Then .Attachments.Add strAttachment
    .Send   'oder .Display
  End With
  On Error GoTo 0
  Set objMail = Nothing
  Set objOL = Nothing
End Sub

« Gruß Sepp »

Beliebteste Forumthreads (12 Monate)

Emailadresse zusammensetzen aus Auflistung

Forumthread: Emailadresse zusammensetzen aus Auflistung

1 Beitrag zum Forumthread Beitrag zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

1
Beitrag zum Forumthread

Beitrag zu diesem Forumthread