Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1600to1604
1600to1604
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Zeile durchsuchen und Spalte dann kopieren

Forumthread: Zeile durchsuchen und Spalte dann kopieren

Zeile durchsuchen und Spalte dann kopieren
09.01.2018 08:49:19
MikeW
Guten Morgen,
ich schreibe gerade meine Bachelorarbeit und möchte in diesem Zuge eine Excel-Datei optimieren.
Es handelt sich um eine Tabelle mit Daten aus einer Anlage. Diese sind sehr unübersichtlich dargestellt.
Nun möchte ich auf einem anderen Reiter eine Vorlage erstellen, welches die benötigten Informationen übersichtlich und sortiert darstellt.
Die Anlage würde die ganzen Daten automatisch in den Reiter Rohdaten hineinkopieren.
Würde mich freuen wenn ihr mir beim erstellen des Makros unterstützen könnt.
Ich möchte in den Rohdaten die Zeile 4 beispielsweiße nach dem Wort "Datum" durchsuchen lassen, wenn das Wort "Datum" gefunden wurde, soll diese Spalte ab der Zeile 5 kopiert werden und in den Reiter "Vorlage" in die zweite Spalte ab der Zeile 5 eingefügt werden.
Diese Funktion würde ich dann für alle benötigten Informationen verwenden um diese übersichtlich und sortiert darzustellen.
Sie sollte am besten ohne einen Button funktionieren, so dass beim öffnen der Datei die Vorlage automatisch befüllt wird.
Im Voraus vielen Dank für eure Unterstützung.
Anzeige

13
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 10:10:12
UweD
Hallo
so?
in ein Modul
Sub dddd()
    Dim TB1, TB2, LR1 As Double, LR2 As Double, EZ1 As Integer, EZ2 As Integer
    Dim Arr, Z, Spalte As Integer
    
    Arr = Array("Datum", "Menge", "Leistung")  ' Suchbegriffe 
    
    Set TB1 = Sheets("Rohdaten")
    Set TB2 = Sheets("Vorlage")
    EZ1 = 4 'Zeile in der gesucht wird 
    EZ2 = 5 'Zielzeile 
    
    For Each Z In Arr
        With WorksheetFunction
            If .CountIf(TB1.Rows(EZ1), Z) > 0 Then 'Ist Suchbegriff da? 
                Spalte = .Match(Z, TB1.Rows(EZ1), 0) 'in welcher Spalte 
                LR1 = TB1.Cells(TB1.Rows.Count, Spalte).End(xlUp).Row 'letzte Zeile der Spalte 
                If LR1 > EZ1 Then 'sind Werte vorhanden? 
                
                    LR2 = .Max(EZ2, TB2.Cells(TB2.Rows.Count, Spalte).End(xlUp).Row)
                    
                    'Reset 
                    TB2.Cells(EZ2, Spalte).Resize(LR2 - EZ2 + 1).ClearContents
                
                    'Übertragen 
                    TB2.Cells(EZ2, Spalte).Resize(LR1 - EZ1).Value = _
                        TB1.Cells(EZ1 + 1, Spalte).Resize(LR1 - EZ1).Value
                End If
            Else
                MsgBox "Suchbegriff '" & Z & "' wurde nicht gefunden"
            End If
        End With
    Next
    
    
End Sub

LG UweD
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 10:52:15
UweD
Hab gerade gesehen, dass du ja in Spalte 2 (dann fortlaufend) beginnen möchtest
und automatisch startend.
dann versuch es so.
Code muss in "DieseArbeitsmappe"
Option Explicit

Private Sub Workbook_Open()
    Dim TB1, TB2, LR1 As Double, LR2 As Double, EZ1 As Integer, EZ2 As Integer
    Dim Arr, Z, Spalte As Integer, ESp2 As Integer
    
    Arr = Array("Datum", "Menge", "Leistung")  ' Suchbegriffe anpassen 
    
    Set TB1 = Sheets("Rohdaten")
    Set TB2 = Sheets("Vorlage")
    EZ1 = 4 'Zeile in der gesucht wird 
    EZ2 = 5 'Zielzeile 
    ESp2 = 2 'erste ZielSpalte 
    
    With WorksheetFunction
        LR1 = .Max(EZ1, TB1.Cells.SpecialCells(xlCellTypeLastCell).Row) 'letze Spalte des gesamten Blattes 
        LR2 = .Max(EZ2, TB2.Cells.SpecialCells(xlCellTypeLastCell).Row)
    
        'Reset inkl. Überschriften 
        TB2.Rows(EZ2 - 1).Resize(LR2 - EZ2 + 2).ClearContents
        
        If LR1 > EZ1 Then 'sind Werte vorhanden? 
    
            For Each Z In Arr
                If .CountIf(TB1.Rows(EZ1), Z) > 0 Then 'Ist Suchbegriff da? 
                    Spalte = .Match(Z, TB1.Rows(EZ1), 0) 'in welcher Spalte 
                
                    'Übertragen inkl. Überschrift 
                    TB2.Cells(EZ2 - 1, ESp2).Resize(LR1 - EZ1).Value = _
                        TB1.Cells(EZ1, Spalte).Resize(LR1 - EZ1 + 1).Value
                    
                    ESp2 = ESp2 + 1 'nächste Spalte 
                Else
                    MsgBox "Suchbegriff '" & Z & "' wurde nicht gefunden"
                End If
            Next
            MsgBox "Rohdaten übernommen!"
            
        Else
            MsgBox "Keine Rohdaten vorhanden!"
        End If
        
    End With
   
End Sub

LG UweD
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 13:26:04
MikeW
Hallo Uwe,
zu aller erst vielen Dank für dein Bemühen.
Ich habe versucht deinen Code auf meine Datei zu übertragen. Ich muss ehrlich sagen, dass ich mich nicht besonders gut auskenne.
Habe die Datei eingefügt, du würdest mir wirklich sehr helfen, wenn du es mir anpassen könntest.
https://www.herber.de/bbs/user/118807.xlsx
Als Code habe ich in das Modul1 folgenden Code eingefügt:
Option Explicit
Private Sub Workbook_Open()
Dim TB1, TB2, LR1 As Double, LR2 As Double, EZ1 As Integer, EZ2 As Integer
Dim Arr, Z, Spalte As Integer, ESp2 As Integer
Arr = Array(Benennung, Datum, Stufe, Typ)  ' Suchbegriffe anpassen
Set TB1 = Sheets(Rohdaten)
Set TB2 = Sheets(Vorlage)
EZ1 = 4 'Zeile in der gesucht wird
EZ2 = 4 'Zielzeile
ESp2 = 1 'erste ZielSpalte
With WorksheetFunction
LR1 = .Max(EZ1, TB1.Cells.SpecialCells(xlCellTypeLastCell).Row) 'letze Spalte des  _
gesamten Blattes
LR2 = .Max(EZ2, TB2.Cells.SpecialCells(xlCellTypeLastCell).Row)
'Reset inkl. Überschriften
TB2.Rows(EZ2 - 1).Resize(LR2 - EZ2 + 2).ClearContents
If LR1 > EZ1 Then 'sind Werte vorhanden?
For Each Z In Arr
If .CountIf(TB1.Rows(EZ1), Z) > 0 Then 'Ist Suchbegriff da?
Spalte = .Match(Z, TB1.Rows(EZ1), 0) 'in welcher Spalte
'Übertragen inkl. Überschrift
TB2.Cells(EZ2 - 1, ESp2).Resize(LR1 - EZ1).Value = _
TB1.Cells(EZ1, Spalte).Resize(LR1 - EZ1 + 1).Value
ESp2 = ESp2 + 1 'nächste Spalte
Else
MsgBox "Suchbegriff '" & Z & "' wurde nicht gefunden"
End If
Next
MsgBox "Rohdaten übernommen!"
Else
MsgBox "Keine Rohdaten vorhanden!"
End If
End With
End Sub
Vielen Dank
Gruß Michael
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 15:01:00
MikeW
Hallo UweD,
ich habe die Fehler entdeckt, wieso der Code bei mir nicht funktioniert hat.
Jetzt habe ich jedoch festgestellt, dass diese Funktion nicht genau dem entspricht was ich mir Vorgestellt habe. Ich habe es anfangs auch falsch beschrieben.
Mein Ziel ist es den Reiter "Vorlage" unterschiedlich zu Formatieren, sprich Farbgestaltung Schriftgröße und so weiter. Das eine nach meinen Vorstellungen leere Tabelle vorbereitet ist.
Nun möchte ich nach Begriffen im Reiter "Rohdaten" Zeile 4 durchsuchen und in diese Tabelle an den richtigen Ort kopieren.
Als Beispiel:
Ich suche nach den Begriffen Datum, Stufe, Typ, ... in Zeile 4 der Rohdaten.
Finde ich den Begriff Datum in Zeile 4 der Rohdaten, dann soll diese Spalte ab Zeile 5 (also ohne die Überschrift "Datum") kopiert werden und in den Reiter "Vorlage" in die dafür fix vorgesehene Spalte 1 ab Zeile 5 eingefügt werden.
Für die jeweiligen Begriffe Stufe, Typ, ... sind dann andere fix vorgesehene Spalte im Reiter "Vorlage" vorgesehen (siehe Datei) die ich dann im Makro hinterlegen möchte.
Wird ein Begriff beispielsweiße nicht gefunden, weil er in den Rohdaten nicht vorkommen, dann bleibt die dafür vorgesehene Spalte im Reiter "Vorlage" leer.
Ich habe die Datei mit einer Veranschaulichung der Tabelle im Reiter "Vorlage" hinzugefügt.
https://www.herber.de/bbs/user/118810.xlsx
Würdest mich wirklich sehr helfen !
Gruß Michael
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 15:04:39
UweD
Hallo
2 Fehler...
- Der Code muss in "DieseArbeitsmappe"
- Du hast einige Anführungszeichen vergessen
Userbild
LG UweD
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 15:12:56
MikeW
Genau diese zwei Fehler habe ich auch gefunden und behoben.
Nur leider wie im Kommentar geschrieben war das Makro nicht zielführend *mein Fehler sorry*.
Könntest du mir vielleicht dazu noch einmal helfen..
Würde mich wirklich freuen wenn ich es hinbekomme.
Gruß Michael
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 16:00:00
UweD
Ok.
jetzt werden die eingetragenen Suchbegriffe der Vorlage gelesen und nacheinander bearbeitet.
(Programm habe ich durch Programmnummer angeglichen)
Option Explicit
Private Sub Workbook_Open()
    Dim TB1, TB2, LR1 As Double, LR2 As Double, LC As Integer, EZ1 As Integer, EZ2 As Integer
    Dim Arr, Z, Spalte As Integer, ESp2 As Integer
    
    Set TB1 = Sheets("Rohdaten")
    Set TB2 = Sheets("Vorlage")
    EZ1 = 4 'Zeile in der gesucht wird 
    EZ2 = 5 'Zielzeile für Daten 
    ESp2 = 1 'erste ZielSpalte 
    
    With TB2
        LC = .Cells(EZ2 - 1, .Columns.Count).End(xlToLeft).Column 'letzte Spalte einer Zeile 
        Arr = .Cells(EZ2 - 1, 1).Resize(1, LC) 'liest die Suchbegriffe 
    End With
    
    With WorksheetFunction
        LR1 = .Max(EZ1, TB1.Cells.SpecialCells(xlCellTypeLastCell).Row) 'letze Spalte des gesamten Blattes 
        LR2 = .Max(EZ2, TB2.Cells.SpecialCells(xlCellTypeLastCell).Row)
    
        'Reset 
        TB2.Rows(EZ2).Resize(LR2 - EZ2 + 1).ClearContents
        
        If LR1 > EZ1 Then 'sind Werte vorhanden? 
    
            For Each Z In Arr
                If .CountIf(TB1.Rows(EZ1), Z) > 0 Then 'Ist Suchbegriff da? 
                    Spalte = .Match(Z, TB1.Rows(EZ1), 0) 'in welcher Spalte 
                
                    'Übertragen inkl. Überschrift 
                    TB2.Cells(EZ2, ESp2).Resize(LR1 - EZ1 + 1).Value = _
                        TB1.Cells(EZ1 + 1, Spalte).Resize(LR1 - EZ1 + 1).Value
                    
                Else
                    MsgBox "Suchbegriff '" & Z & "' wurde nicht gefunden"
                End If
                ESp2 = ESp2 + 1 'nächste Spalte 
            Next
            MsgBox "Rohdaten übernommen!"
            
        Else
            MsgBox "Keine Rohdaten vorhanden!"
        End If
        
    End With
   
End Sub

LG UweD
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 16:21:13
MikeW
Hallo UweD,
wirklich, vielen vielen Dank für deine Bemühungen. Leider kann es so aber nicht funktionieren :(
Nach den Begriffen, nach denen ich in Zeile 4 der "Rohdaten" suchen möchte stimmen nicht immer mit den Überschriften in der Tabelle überein. Ansonsten würde dein Makro klasse funktionieren. Die tatsächlichen Suchbegriffe möchte ich dann erst im Makro hinterlegen.
Ich versuche es mal, den Code in "normaler Sprache zu schreiben":D. Hoffe es hilft dir weiter und du kannst besser verstehen was ich benötige.
Option Explicit
Private Sub Workbook_Open()
'Suchbegriffe definieren
Dim "Datum" As String
Dim "Stufe" As String
'Abfrage in Reiter "Rohdaten" in Zeile 4 durchführen ob Wort "Datum" vorhanden
If "Datum" in Reiter "Rohdaten" in Zeile 4 Then
Kopieren dieser Spalte ab Zeile 5
Einfügen in Reiter "Vorlage" in Spalte A ab Zeile 4
Else
Nichts soll passieren
'Abfrage in Reiter "Rohdaten" in Zeile 4 durchführen ob Wort "Stufe" vorhanden
If "Stufe" in Reiter "Rohdaten" in Zeile 4 Then
Kopieren dieser Spalte ab Zeile 5
Einfügen in Reiter "Vorlage" in Spalte B ab Zeile 4
Else
Nichts soll passieren
End Sub
So würde ich für jeden Suchbegriff eine If Funktion einfügen.
Ich hoffe dieses Beispiel hilft dir weiter, ich versuche es schon den ganzen Tag aber komme leider nicht weiter...
Noch einmal vielen Dank im Voraus !
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 17:03:06
UweD
So.
also wieder mit vordefinierten Suchbegriffen
Option Explicit
Private Sub Workbook_Open()
    Dim TB1, TB2, LR1 As Double, LR2 As Double, LC As Integer, EZ1 As Integer, EZ2 As Integer
    Dim Arr, Z, Spalte As Integer, ESp2 As Integer
    
    Set TB1 = Sheets("Rohdaten")
    Set TB2 = Sheets("Vorlage")
    EZ1 = 4 'Zeile in der gesucht wird 
    EZ2 = 5 'Zielzeile für Daten 
    ESp2 = 1 'erste ZielSpalte 
    
    Arr = Array("Datum", "Stufe", "Typ") 'die Suchbegriffe für Rohdaten 
    
    With WorksheetFunction
        LR1 = .Max(EZ1, TB1.Cells.SpecialCells(xlCellTypeLastCell).Row) 'letze Spalte des gesamten Blattes 
        LR2 = .Max(EZ2, TB2.Cells.SpecialCells(xlCellTypeLastCell).Row)
    
        'Reset ohne Überschriften 
        TB2.Rows(EZ2).Resize(LR2 - EZ2 + 1).ClearContents
        
        If LR1 > EZ1 Then 'sind Werte vorhanden? 
    
            For Each Z In Arr
                If .CountIf(TB1.Rows(EZ1), Z) > 0 Then 'Ist Suchbegriff in Zeile EZ1 =4 vorhanden? 
                    Spalte = .Match(Z, TB1.Rows(EZ1), 0) 'in welcher Spalte steht der Begriff 
                
                    'Übertragen ohne Überschrift 
                    TB2.Cells(EZ2, ESp2).Resize(LR1 - EZ1 + 1).Value = _
                        TB1.Cells(EZ1 + 1, Spalte).Resize(LR1 - EZ1 + 1).Value
                    
                Else
                    'Fehlermeldung, wenn der Suchbegriff in Rohdaten nicht gefunden wird 
                    MsgBox "Suchbegriff '" & Z & "' wurde nicht gefunden"
                End If
                
                ESp2 = ESp2 + 1 'nächste Spalte 
                
            Next
            'Fertig 
            MsgBox "Rohdaten übernommen!"
            
        Else
            'Keine Daten unter Zeile EZ1 =4 vorhanden 
            MsgBox "Keine Rohdaten vorhanden!"
        End If
        
    End With
   
End Sub

LG UweD
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
09.01.2018 22:07:09
MikeW
Hallo UweD,
ja nur das Problem an diesem Makro ist, dass ich nicht bestimmen kann, in welche Spalte es kopiert werden soll.
Aktuell werden sie ja nach der Reihenfolge der Suchbegriffe im Makro in den Reiter "Vorlage" kopiert.
Ich will in dem Makro festlegen können, dass ein Suchbegriff in Spalte XY im Reiter "Vorlage" hinein kopiert werden soll.
Das beispielsweiße "Datum" immer in Spalte A kopiert werden soll und "Stufe" in Spalte E.
Ansonsten würde alles wunderbar passen.
Würde mich sehr freuen, wenn wir das hinbekommen würden :)
Wünsche dir noch einen schönen Abend !
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
10.01.2018 08:54:40
UweD
Hallo nochmal
dann mit 2 Arrays
Das 1. mit den Suchbegriffen, das 2. mit den Spaltennummern, wo die Daten eingefügt werden sollen.
(Anzahl muss dann gleich sein)
Option Explicit
Private Sub Workbook_Open()
    Dim TB1, TB2, LR1 As Double, LR2 As Double, LC As Integer, EZ1 As Integer, EZ2 As Integer
    Dim ArrBegr, ArrWo, Z As Integer, Spalte As Integer
    
    Set TB1 = Sheets("Rohdaten")
    Set TB2 = Sheets("Vorlage")
    EZ1 = 4 'Zeile in der gesucht wird 
    EZ2 = 5 'Zielzeile für Daten 
    
    ArrBegr = Array("Datum", "Stufe", "Typ") 'die Suchbegriffe für Rohdaten 
    ArrWo = Array(1, 2, 4) 'die Einfügespalten für die Suchbegriffe 
    
    With WorksheetFunction
        LR1 = .Max(EZ1, TB1.Cells.SpecialCells(xlCellTypeLastCell).Row) 'letze Spalte des gesamten Blattes 
        LR2 = .Max(EZ2, TB2.Cells.SpecialCells(xlCellTypeLastCell).Row)
    
        'Reset ohne Überschriften 
        TB2.Rows(EZ2).Resize(LR2 - EZ2 + 1).ClearContents
        
        If LR1 > EZ1 Then 'sind Werte vorhanden? 
    
            For Z = Lbound(ArrBegr, 1) To Ubound(ArrBegr, 1)
                If .CountIf(TB1.Rows(EZ1), ArrBegr(Z)) > 0 Then 'Ist Suchbegriff in Zeile EZ1 =4 vorhanden? 
                    Spalte = .Match(ArrBegr(Z), TB1.Rows(EZ1), 0) 'in welcher Spalte steht der Begriff 
                
                    'Übertragen ohne Überschrift 
                    TB2.Cells(EZ2, ArrWo(Z)).Resize(LR1 - EZ1 + 1).Value = _
                        TB1.Cells(EZ1 + 1, Spalte).Resize(LR1 - EZ1 + 1).Value
                    
                Else
                    'Fehlermeldung, wenn der Suchbegriff in Rohdaten nicht gefunden wird 
                    MsgBox "Suchbegriff '" & ArrBegr(Z) & "' wurde nicht gefunden"
                End If
                
            Next
            'Fertig 
            MsgBox "Rohdaten übernommen!"
            
        Else
            'Keine Daten unter Zeile EZ1 =4 vorhanden 
            MsgBox "Keine Rohdaten vorhanden!"
        End If
        
    End With
   
End Sub
LG UweD
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
10.01.2018 17:26:29
MikeW
Guten Abend UweD,
vielen Dank ! Genau so habe ich es mir vorgestellt. Konnte es auch bereits komplett in mein kleines Projekt integrieren.
Jedoch ist mir eine notwendige Optimierung aufgefallen, bei der ich hoffe, dass du mir dabei helfen kannst.
In den Rohdaten gibt es mehrmals Spalten, die nicht vollständig befüllt sind. Beispielsweise gibt es Spalten mit den Überschriften "Datum" und "Date".
In einer Zeile der beiden Überschriften sind niemals beide Spalten gleichzeitig befüllt. Entweder gibt es einen Eintrag bei "Datum" oder bei "Date".
Nun habe ich die Überlegung, bevor die Spalten in den Reiter "Vorlage" kopiert wird, beide Spalten zu überlagern und erst anschließend dann in eine einzige Spalte im Reiter "Vorlage" zu kopieren.
Denkst du hierzu gibt es eine Möglichkeit und du könntest mir helfen?
Wünsche dir einen schönen Abend !
Anzeige
AW: Zeile durchsuchen und Spalte dann kopieren
12.01.2018 11:10:37
UweD
Hallo nochmal
hab das für Datum / Date eingebaut.
Option Explicit
Private Sub Workbook_Open()
    Dim TB1, TB2, LR1 As Double, LR2 As Double, LC As Integer, EZ1 As Integer, EZ2 As Integer
    Dim ArrBegr, ArrWo, Z As Integer, Spalte As Integer, SpTmp As Integer
    
    Set TB1 = Sheets("Rohdaten")
    Set TB2 = Sheets("Vorlage")
    EZ1 = 4 'Zeile in der gesucht wird 
    EZ2 = 5 'Zielzeile für Daten 
    
    ArrBegr = Array("Datum", "Stufe", "Typ") 'die Suchbegriffe für Rohdaten 
    ArrWo = Array(1, 2, 4) 'die Einfügespalten für die Suchbegriffe 
    
    With WorksheetFunction
        LR1 = .Max(EZ1, TB1.Cells.SpecialCells(xlCellTypeLastCell).Row) 'letze Spalte des gesamten Blattes 
        LR2 = .Max(EZ2, TB2.Cells.SpecialCells(xlCellTypeLastCell).Row)
    
    
    
        'Reset ohne Überschriften 
        TB2.Rows(EZ2).Resize(LR2 - EZ2 + 1).ClearContents
        
        If LR1 > EZ1 Then 'sind Werte vorhanden? 
    
            For Z = Lbound(ArrBegr, 1) To Ubound(ArrBegr, 1)
                If .CountIf(TB1.Rows(EZ1), ArrBegr(Z)) > 0 Then 'Ist Suchbegriff in Zeile EZ1 =4 vorhanden? 
                    Spalte = .Match(ArrBegr(Z), TB1.Rows(EZ1), 0) 'in welcher Spalte steht der Begriff 
                    
                    'Datum / Date normieren 
                    If ArrBegr(Z) = "Datum" Then
                        If .CountIf(TB1.Rows(EZ1), "Date") > 0 Then
                            SpTmp = .Match("Date", TB1.Rows(EZ1), 0)
                            With TB1
                       
                                LC = .Cells.SpecialCells(xlCellTypeLastCell).Column + 1 'nächste freie Spalte des gesamten Blattes 
                                
                                'Hilfsspalte mit Formel; Wenn kein Datum dann nimm Date 
                                .Range(.Cells(EZ1 + 1, LC), .Cells(LR1, LC)).FormulaR1C1 = _
                                    "=IF(RC" & Spalte & "="""",RC" & SpTmp & ",RC" & Spalte & ")"
                                
                                Spalte = LC
                                MsgBox "Datum / Date vereint"
                            End With
                        Else
                            MsgBox "Spalte 'Date' wurde nicht gefunden"
                        End If
                    End If
                    
                    
                    'Übertragen ohne Überschrift 
                    TB2.Cells(EZ2, ArrWo(Z)).Resize(LR1 - EZ1 + 1).Value = _
                        TB1.Cells(EZ1 + 1, Spalte).Resize(LR1 - EZ1 + 1).Value
                        
                    'Temoräre DatumSpalte löschen 
                    If LC > 0 Then TB1.Columns(LC).ClearContents
                    
                Else
                    'Fehlermeldung, wenn der Suchbegriff in Rohdaten nicht gefunden wird 
                    MsgBox "Suchbegriff '" & ArrBegr(Z) & "' wurde nicht gefunden"
                End If
                
            Next
            'Fertig 
            MsgBox "Rohdaten übernommen!"
            
        Else
            'Keine Daten unter Zeile EZ1 =4 vorhanden 
            MsgBox "Keine Rohdaten vorhanden!"
        End If
        
    End With
   
End Sub

LG UweD
Anzeige

Forumthreads zu verwandten Themen

Anzahl unterschiedl. Werte in Spalte zählen
Jakob

Hallo,
ein ähnliches Problem wurde hier im Forum schon einmal diskutiert. (https://www.herber.de/forum/archiv/632to636/t635773.htm)
Meine Problem:
Wie kann ich die Anzahl unterschiedlicher Einträge/Werte einer Spalte erhalten, ohne dass diese vorgegeben werden ( also ohne die Verwe...
14.08.2008 18:16:11
Thread-ID: 1001934
2 Beiträge
Anzeige
Zeilen einfärben abhängig von Zellwerten
Zellwerten

Hi Leute
Da ich nicht weiß, wie ich nach meinem Problem suchen kann, beschreibe ich es einfach mal kurz. Vielleicht kann mir ja jemand helfen.
Ich habe ein Excel-File, das xSpalten hat und xZeilen.
In einer Spalte (in meinem Fall Spalte F) stehen die verschiedenen Auftragsnummern, a...
18.08.2008 16:57:26
Thread-ID: 1002687
6 Beiträge
In Spalte nach Anzahl eines Begriffs suchen?
Lauren

Hall Leute!
ich will nach einem Begriff, in meinem Fall nach "SUMs" in der Spalte C suchen und wissen wie oft es in der Spalte vorkommt.
Bei Berechnungen funktioniert es mit ZÄHLENWENN ohne Probleme aber wie erhalte ich die "absolute" Zahl?
Vielen Dank für Eure Hilfe!
Grüße
...
19.08.2008 11:08:23
Thread-ID: 1002846
5 Beiträge
Anzeige
Letzter Wert einer Spalte (Matrixformel)
{mskro}

Hallo Excelaner,
ich benötige mal wieder eine Hilfestellung.
Es soll der Wert in einer Spalte angezeigt werde, der in der untersten Zeile steht.
Mittels der Recherche habe ich nun folgende MatrixFormel erstellt:
=INDEX(Z1:Z5000;MAX(WENN(Z1:Z5000"";ZEILE(1:5000)));1)
Nur wird...
28.08.2008 09:59:21
Thread-ID: 1005303
9 Beiträge
Anzeige
Letzen wert in Zeile(nicht Spalte)
hary

Nabend alle miteinander
In einer bestimmten Zeile suche ich den letzten Eintrag. Bis zu diesem soll gefaerbt werden. Mit diesem Code faerbe ich den ganzen Bereich, es soll aber nur bis zum letzten Eintrag in der Zeile gefaerbt werden. Da von links nach rechts gefaerbt.
Case Is = Cells...
28.08.2008 21:25:00
Thread-ID: 1005592
5 Beiträge
Zelleninhalt (Text) in 2 Spalten teilen
El.

Hallo!
Habe eine Spalte in der Artikelname und Artikelmerkmale, durch drei Punkte getrennt "...", zusammen stehen. Beispiel: Lecker Whisky 21 Jahre ... Lieferung in hochwertiger Schatulle
Wie krieg ich nun den Text links der Punkte in eine extra Spalte und rechts der Punkte in eine extr...
03.09.2008 16:35:00
Thread-ID: 1007155
4 Beiträge
von Datum bis Datum suchen und Werte in die Spalte
Datum

Hallo liebe Excel-Könner,
ich habe folgendes Problem und finde keine Lösung.
Ich habe in Spalte A von 2006 bis heute Datum stehen, über eine UserForm möche ich in zwei TextBoxen von bis Datum eintragen und in Spalte B in diesem Bereich den WertX.
Ich hoffe Ihr könnt mir helfen!
...
07.09.2008 09:31:20
Thread-ID: 1007931
8 Beiträge
Anzeige
Spaltentrennzeichen nach speichern in Text-Datei
Michael

Hallo
ich habe ein Problem. Vielleicht ist es schwierig, vielleicht aber auch nicht.
Ich habe eine Text-Datei mit Spaltentrennzeichen "|" (besser als ";" der Übersichtlichtlichkeit halber) und verschiedenen Längen der Spalten.
Ich will diese in Excel überarbeiten und als Text-Dat...
11.09.2008 09:28:00
Thread-ID: 1008978
3 Beiträge
Mittelwertberechn. mit var. Spaltenlänge
Falk

Hallo,
Zur Situation
in einer Excelspalte (z.B. A) füge ich - aus einem anderen Programm - kopierte Zahlen ein. Excel schreibt die, in Spalte A, eingefügten Zahlen untereinander. In der Spalte B berechne ich dann den Mittelwert wie folgt: =SUMME(A2:A1872)/1871
Mein Problem
Weil...
15.09.2008 11:21:00
Thread-ID: 1009725
5 Beiträge
Text in Spalten
Simone

Hallo zusammen,
ich hab ein wohl eher triviales Problem, komme aber trotzdem einfach nicht weiter.
Ich füge in ein Arbeitsblatt Daten aus einem anderen Programm ein. Jetzt habe ich mehrmals die Funktion 'Text in Spalten' verwendet / ausprobiert, und wenn ich jetzt wieder Daten in A1 ein...
16.09.2008 13:54:00
Thread-ID: 1010092
3 Beiträge
Wert innerhalb Array suchen
David

Hallo VBAler,
wenn ich ein Array in der Form
treffer_n(n)
habe, gibt es da eine schnelle und einfache Möglichkeit zu prüfen, ob ein bestimmter Wert in diesem Array vorhanden ist, oder muss ich alle Werte per Schleife einzeln prüfen lassen?
Gruß
David
19.09.2008 08:48:14
Thread-ID: 1010894
3 Beiträge
Spalte mit x = Wert möglich ?
Petra

Hallo
Ich möchte gerne wenn in Spalte B3 ein x eingetragen wird, das dann in Spalte B3 der Wert aus Spalte B1 eingetragen wird.
Ich weiß das es per Formel =Wenn(B3="x";B1;0) geht, aber dann müßten wir hier Behelfsspalten einbauen was nicht gewünscht wird.
Habe es per Bedingter Forma...
23.09.2008 15:34:17
Thread-ID: 1011775
21 Beiträge
Anzeige

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Anzeige