Werte in Matrix, Spalte und Zeile auslesen lassen

Forumthread: Werte in Matrix, Spalte und Zeile auslesen lassen

15.01.2025 11:11:00

DannyR

Guten Tag zusammen,

Ich habe die beiliegende Matrix.
Userbild

Nun möchte ich in einer sep. Liste alle Kurse auflisten.
somit:
Datum1 Beruf2
Datum1 Beruf4
Datum2 Beruf1
Datum2 Beruf3
Datum3 Beruf3
Datum4 Beruf4

Kann mir jemand mit der Formel für die Datumsspalte sowie Berufsspalte helfen:
Danke vielmals:
Danny

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Werte in Matrix, Spalte und Zeile auslesen lassen

15.01.2025 11:31:07

Hola,
in A9:

=WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$5="x");ZEILE(A1)));"")

in B9:

=WENNFEHLER(INDEX($A$2:$A$5;AGGREGAT(15;6;ZEILE($A$2:$A$5)-1/(($B$2:$E$5="x")*($B$1:$E$1=A9));ZÄHLENWENN($A$9:A9;A9)));"")

Gruß,
steve1da

AW: Werte in Matrix, Spalte und Zeile auslesen lassen

15.01.2025 15:12:17

Yal

Hallo Danny,

diese Aufgabe nennt man entpivotieren und ist der Grund, warum man Power Query kennenlernen sollte:

- Stelle in A1 einen Überschrift zu der Spalte A: "Beruf"
- klicke A1 an
- Menü "Einfügen", "Tabelle". Du hast jetzt eine Tabelle, auch "intelligente Tabelle" benannt.
- Menü "Daten", "Aus Tabelle/Bereich", "hat Überschrift" anhaken.
- Du bist in Power Query Editor
- rechts in der Liste der angewendete Schritte, lösche den zweiten Schritt "geänderter Typ"
- markiere die erste Spalte "Beruf",
- Menü "Transformieren", "Spalte entpivotieren", "andere Spalten entpivotieren" (die Zellen mit "null" werden dabei aussortiert)
- Menü "Datei", "Schliessen & laden"

Wenn jetzt eine neue Zeile oder Spalte in der Quelle dazu kommt, ergänzt sich die Tabelle automatisch. Dann auf die Ergebnistabelle gehen, rechtsklicken und "Aktualisieren".

Wenn Du mehr über Power Query erfahren möchtest, empfehle ich den Tutorial https://excelhero.de/power-query/power-query-ganz-einfach-erklaert

VG
Yal

AW: Werte in Matrix, Spalte und Zeile auslesen lassen

15.01.2025 12:59:51

DannyR

Hallo steve1da,

Herzlichen Dank für deine prompte hilfreiche Antwort!
Klappt wunderbar.
Könnte man noch ergänzen, dass er alle Daten abholt welche ein X oder (X) in der Matrix haben?

Vielen Dank und Gruss
DannyR

AW: Werte in Matrix, Spalte und Zeile auslesen lassen

15.01.2025 13:25:46

=WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/(($B$2:$E$5="x")+($B$2:$E$5="(x)"));ZEILE(A1)));"")

=WENNFEHLER(INDEX($A$2:$A$5;AGGREGAT(15;6;ZEILE($A$2:$A$5)-1/((($B$2:$E$5="x")+($B$2:$E$5="(x)"))*($B$1:$E$1=A9));ZÄHLENWENN($A$9:A9;A9)));"")

Oder etwas kürzer wenn nach einem X in den Zellen gesucht werden soll, egal wo es steht und was noch dabei steht:

=WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/(ISTZAHL(SUCHEN("x";$B$2:$E$5)));ZEILE(A1)));"")

=WENNFEHLER(INDEX($A$2:$A$5;AGGREGAT(15;6;ZEILE($A$2:$A$5)-1/((ISTZAHL(SUCHEN("x";$B$2:$E$5)))*($B$1:$E$1=A9));ZÄHLENWENN($A$9:A9;A9)));"")

AW: Werte in Matrix, Spalte und Zeile auslesen lassen

15.01.2025 14:03:35

DannyR

Herzlichen Dank, hat perfekt geklappt.
Grosse Dankeschön!

Werte in Matrix, Spalte und Zeile auslesen lassen

Forumthread: Werte in Matrix, Spalte und Zeile auslesen lassen

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Werte in Matrix, Spalte und Zeile auslesen lassen

Forumthread: Werte in Matrix, Spalte und Zeile auslesen lassen

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread