Zelle mit aktuellem Datum markieren

mike49 · 2013-11-25T23:04:03+00:00

Hallo zusammen, ich habe eine Tabelle mit einer Jahresübersicht im Querformat.Im Bereich B6:AF6 stehen die festen Zahlen 1 bis 31 für die Tage. In den Zeilen darunter sind die Monate für Stundeneinträge angeordnet. Wie kann man erreichen, dass beim Öffnen der Mappe die Zelle des aktuellen Tages für den Stundeneintrag angesprungen und hervorgehoben wird. Es müsste z.B. am heutigen Tag (25.11.) die Zelle Z39 für den Stundeneintrag angesprungen und hervorgehoben werden. Kann man das machen? VBA? Zur besseren Veranschaulichung lade ich die Datei mal hoch.Vielleicht nimmt sich jemand der Sache an. https://www.herber.de/bbs/user/88256.xlsm Gruß mike49

…Mike; ;-X
hoffentlich hast du deine Mappe nun nicht immer wieder neu hochgeladen, denn das wäre inzwischen rekordverdächtig (meine UpLoads mitgerechnet) und wohl kaum im Sinne des Betreibers!
Auch deshalb bekommst du jetzt nur eine Anleitung von mir: ;-]
1. VBE öffnen und DieseArbeitsmappe im Verzeichnisbaum auswählen und öffnen.
2. Im linken KopfMenü der großen weißen Fläche rechts Workbook auswählen → standardmäßig wir sofort der Rahmen der Workbook_Open-Prozedur angelegt.
3. In die Leerzeile zwischen Kopf und Fuß derselben schreibst du Call StartZelle.
4. In eines deiner normalen Module kopierst du folgd PgmCode:

Sub StartZelle()
Const zlOff As Long = 2, adMonBer$ = "A7:A40"
Dim axDatum As Variant, monBer As Range
axDatum = Split(Format(Now, "yyyy-m d"))
Set monBer = Range(adMonBer)
monBer.Cells(WorksheetFunction.Match(CLng(CDate(axDatum(0) & "-1")), _
monBer, 0)).Offset(zlOff, CInt(axDatum(1))).Activate
Set monBer = Nothing
End Sub

Die Konstante zlOff habe ich angelegt, falls du wieder mal Zeilen einfügen willst, dann musst du nur ihren Wert ändern. Zusätzliche Spalten vor den Tagen sind allerdings nicht berücksichtigt.
Die Vorgehensweise über eine separate, von der EreignisProzedur aufgerufene Subroutine hat den Vorteil, dass du sie auch anderweitig einsetzen kannst, zB per Aufruf über einen Button, aus dem Makro-Menü oder einer anderen EreignisProz wie bspw Worksheet_Activate (dann wird sie immer aufgerufen, wenn das Blatt geöffnet wird, falls mal noch andere dazukommen sollten).
Gruß Luc :-?

…und die Mappe so hochgeladen, Mike?
Das habe ich nicht überprüft und einen solchen Fehler auch nicht abgefangen. Dann muss man das anders machen, nämlich sich ggf nach der Jahreszahl in der Tab richten:

Sub StartZelle()
Const zlOff As Long = 2, adJahrZ$ = "F3", adMonBer$ = "A7:A40"
Dim axDatum As Variant, monBer As Range
axDatum = Split(Range(adJahrZ).Text & Format(Now, "-m d"))
Set monBer = Range(adMonBer)
monBer.Cells(WorksheetFunction.Match(CLng(CDate(axDatum(0) & "-1")), _
monBer, 0)).Offset(zlOff, CInt(axDatum(1))).Activate
Set monBer = Nothing
End Sub

Aber eigentl ist das Quatsch, denn in anderen Jahren als dem aktuellen müssten eigentl andere Zellen ausgewählt wdn:
1. in Vorjahren evtl der 31.12. oder sonstwas bzw gar nichts,
2. in Folgejahren der 1.1. oder ebenfalls dito.
Deshalb schlage ich eher Folgendes vor:

Sub StartZelle()
Const zlOff As Long = 2, adJahrZ$ = "F3", adMonBer$ = "A7:A40"
Dim fxJahr As Long, axDatum As Variant, monBer As Range
On Error GoTo fx
fxJahr = Range(adJahrZ)
If fxJahr  Year(Now) Then Err.Raise xlErrNum
axDatum = Split(Format(Now, "yyyy-m d"))
Set monBer = Range(adMonBer)
monBer.Cells(WorksheetFunction.Match(CLng(CDate(axDatum(0) & "-1")), _
monBer, 0)).Offset(zlOff, CInt(axDatum(1))).Activate
GoTo ex
fx: If Err.Number = xlErrNum Then
MsgBox "Das eingestellte Jahr entspricht nicht dem aktuellen!", _
vbExclamation, "Jahresvergleich"
Else: MsgBox Err.Description, vbCritical, "Interner Fehler " & CStr(Err.Number)
End If
ex: Set monBer = Nothing
End Sub

Mann, du bringst mich noch um den Verstand… ;-]
Gruß Luc :-?

Zelle mit aktuellem Datum markieren

Forumthread: Zelle mit aktuellem Datum markieren

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Zelle mit aktuellem Datum markieren

Forumthread: Zelle mit aktuellem Datum markieren

14 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

14
Beiträge zum Forumthread

Beiträge zu diesem Forumthread