Monate aus Datumsbereich zählen

Forumthread: Monate aus Datumsbereich zählen

04.03.2022 14:10:32

Raffaele

Hallo zusammen,
ich möchte wissen, wie hoch meine Auslastung pro Monat ist.
Zur Auswertung habe ich eine Liste meiner Kunden, die von Tag "x" bis Tag "y" von mir betreut werden.
Anbei mal ein Screenshot, wie es aussehen kann.
Userbild

Vielen Dank im Voraus!
LG
Raffaele

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Monate aus Datumsbereich zählen

04.03.2022 14:14:56

Hola,


=SUMMENPRODUKT((MONAT($E$6:$E$7)=MONAT(A5&0)))

Gruß,
steve1da

AW: Monate aus Datumsbereich zählen

04.03.2022 14:19:51

Raffaele

So einfach kann es dann manchmal sein... Danke!

AW: Monate aus Datumsbereich zählen

04.03.2022 15:04:58

Raffaele

Ich hätte noch eine Steigerung der Schwierigkeit zu meiner Anfrage... :-)
Wie kann man das Lösen, wenn in der "von" Spalte noch das Jahr 2021 steht`?
Also die Betreuung eines Mandanten vom 04.11.2021 bis zum 13.03.2022 geht.

AW: Anzahl "zählen" für Monate im akt. Jahr ...

04.03.2022 16:29:25

neopa

Hallo Raffaele,
... wenn in A4 "Januar" steht und in E6:F99 die Kundendaten, dann in B4:

=SUMMENPRODUKT((E$6:E$99&lt=MONATSENDE((A4&"-"&JAHR(HEUTE()))+0;0))*(F$6:F$99&gt=(A4&"-"&JAHR(HEUTE() ))+0))
und nach unten kopieren.
Gruß Werner
.. , - ...

Hier mit Volldynamik (xl365)

04.03.2022 17:18:34

lupo1

B2:C4: 3x Von-Bis-Datümer (also keine Bistümer)
E1: =DATUM(2021;SEQUENZ(10;;10);1) benDefFmt M.JJ
F1: =LAMBDA(a;b;
NACHZEILE(b;LAMBDA(b;SUMME(--(
NACHZEILE(a;LAMBDA(a;
MAX(;MIN(MONATSENDE(b;0)+1;REST(a;1)/1%%%+1)-MAX(b;KÜRZEN(a)))))&gt0)))))
(B2:B4+C2:C4%%%;E1#)

Und hier mit pivotähnl. Super-Volldynamik (Datei)

05.03.2022 09:50:58

lupo1

https://www.herber.de/bbs/user/151566.xlsx

AW: alternativ noch ne "Halbdynamik"-Lösung ...

05.03.2022 19:17:46

neopa

Hallo,
... welche mit wesentlich weniger Formelaufwand erstellt werden kann. "Halbdynamik" deshalb, obwohl alle Ergebnisse auch für Datenerweiterung dynamisch ermittelt werden, sind evtl. zusätzlich ein paar Mausklicks erforderlich. Diese jedoch nur nach solchen Datenänderungen, die Einfluss auf die Ergebnisse der Folgejahre haben oder wenn 0-Ergebnisswerte im akt. Jahr ausgefiltert werden sollen.
Meine Alternative ist auch in älteren XL-Versionen (EDATUM() muss vorhanden sein) einsetzbar. Ich z.B. habe noch keine akt. XL-Version und kann lupos Lösung somit auch nicht einsetzen. Allerdings soll meiner Kenntnis nach LAMBDA() auch nicht in allen aktuellen XL-Versionen zur Verfügung stehen.
In meiner untenstehenden alternativen Vorschlag sind die Kundendatendaten als "Intelligente" Tabelle formatiert, dadurch werden auch schon zusätzliche Kundendaten automatisch berücksichtigt. Die "Intelligente" Tabelle hab ich im Beispiel tab_05 benannt. Auch die Auswertungstabelle in A:B ist als eine solche formatiert, ist hier aber nicht zwingend notwendig, nur müssen die Formel A4:B4 zuvor weit genug nach unten kopiert werden.
Die erwähnten zusätzlichen Mausklicks sind bei meinem alternativen Vorschlag nur dann notwendig, wenn wie im Beispiel einige Monate des aktuellen Jahres mit Ergebnisanzahl =0 ausgefiltert werden sollen oder man auch bei neuen Kundendaten automatisch ermittelte Anzahl für Monate des/der Folgejahre/s sehen will, die evtl. da noch ausgefiltert sind.
Bei evtl. Anmerkungen / Nachfragen hierzu, kann ich frühesten erst in ein paar Tagen darauf reagieren können.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	akt: 2022
2
3	Monat	Anzahl		Kunde	von	bis
4	11.2021	1		a	17.11.2021	03.03.2022
5	12.2021	1		b	02.02.2022	31.03.2022
6	01.2022	1		c	03.03.2022	05.05.2022
7	02.2022	2		d	04.04.2022	04.04.2022
8	03.2022	3		e	01.07.2022	03.08.2022
9	04.2022	2		f	14.11.2022	04.01.2023
10	05.2022	1
12	07.2022	1
13	08.2022	1
16	11.2022	1
17	12.2022	1
18	01.2023	1
25

Zelle	Formel
A1	=HEUTE()
A4	=WENN(ZEILE(A1)&gtDATEDIF(MIN(tab_05[von]);MAX(tab_05[bis]);"M")+2;"";EDATUM(--("1."&TEXT(MIN(tab_05[von]);"MM.JJJ"));ZEILE(A1)-1))
B4	=WENN([@Monat]="";"";SUMMENPRODUKT((tab_05[von]&lt=MONATSENDE([@Monat];0))*(tab_05[bis]&gt=[@Monat])))

Zelle	bedingte Formatierung...	Format
A4	1: JAHR($A4)>JAHR($A$1)	abc

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Gruß Werner
.. , - ...

Neue Funktionen für Excel (nochmal für alle)

08.03.2022 14:57:34

lupo1

1. Bestehende Kaufversionen bekommen nur das aus dem Abo-Welt-Stand, was bei Veröffentlich schon da ist. Nachgerüstet - etwa bei Patches - wurde m.W. bislang noch nie etwas. Bei TEXTVERKETTEN war es besonders knapp: Es rutschte gerade noch in XL2019 hinein, welches im November 2018 auf den Markt kam. TEXTVERKETTEN war nur einen Monat älter.
2. LAMBDA soll nun jeder bekommen. Gemäß Punkt 1. bedeutet das: Alle 365er (also nicht nur Insider) und alle zukünftigen Kaufversionen (also ab xl2024).
3. LAMBDA wurde zwar am 7.2. auch in XLWeb gezeigt, aber es führte dort zu Nichterkennungen von LAMBDA- und Helper-Funktionen und Lokalisierungen (benannte LAMBDAs klappten aber schon). Daher ist es momentan bis zu einer Behebung der Probleme dort suspendiert.

Beliebteste Forumthreads (12 Monate)

Forumthread: Monate aus Datumsbereich zählen

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Monate aus Datumsbereich zählen

Forumthread: Monate aus Datumsbereich zählen

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread